dev-python/ipywidgets: Remove unnecessary jupyterlab_widgets dep

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-python/ipywidgets/ipywidgets-7.6.5-r2.ebuild b/dev-python/ipywidgets/ipywidgets-7.6.5-r2.ebuild
new file mode 100644
index 000000000000..ef21542a3c78
--- /dev/null
+++ b/dev-python/ipywidgets/ipywidgets-7.6.5-r2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython HTML widgets for Jupyter"
+HOMEPAGE="https://ipywidgets.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/ipykernel-4.5.1[${PYTHON_USEDEP}]
+	>=dev-python/ipython_genutils-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/widgetsnbextension-3.5.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}/${PN}-7.6.3-py310.patch"
+)
+
+src_prepare() {
+	# upstream hack to autoconfigure ipywidgets in jupyter
+	# we don't have jupyterlab_widgets packaged
+	sed -i -e '/jupyterlab_widgets/d' setup.py || die
+	distutils-r1_src_prepare
+}