1 files changed, 70 insertions, 0 deletions
diff --git a/x11-misc/lightdm/lightdm-1.0.0.ebuild b/x11-misc/lightdm/lightdm-1.0.0.ebuild
new file mode 100644
index 0000000..ba36e36
--- /dev/null
+++ b/x11-misc/lightdm/lightdm-1.0.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=3
+inherit eutils pam
+
+DESCRIPTION="A lightweight display manager"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
+SRC_URI="http://launchpad.net/lightdm/trunk/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk +introspection nls qt4 vala"
+
+VALASLOT="0.12"
+
+RDEPEND="
+	>=dev-libs/glib-2.26:2
+	x11-libs/libxcb
+	x11-libs/libXdmcp
+	x11-libs/libX11
+	x11-libs/libxklavier
+	virtual/pam
+	gtk? ( x11-libs/gtk+:2 )
+	introspection? ( dev-libs/gobject-introspection )
+	nls? ( virtual/libintl )
+	qt4? (
+		x11-libs/qt-core:4
+		x11-libs/qt-dbus:4
+		x11-libs/qt-gui:4
+	)
+	vala? ( dev-lang/vala:${VALASLOT} )
+	"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )
+	"
+
+pkg_setup() {
+	export VALAC="$(type -p valac-${VALASLOT})"
+
+	enewgroup lightdm
+	enewuser lightdm -1 -1 /var/lib/lightdm lightdm
+}
+
+src_configure() {
+	econf \
+		--localstatedir="${EPREFIX}/var" \
+		--disable-static \
+		--disable-dependency-tracking \
+		--with-greeter-user=lightdm \
+		--with-xserver-binary="${EPREFIX}/usr/bin/X" \
+		--with-xsession-dir="${EPREFIX}/usr/share/xsessions" \
+		$(use_enable gtk liblightdm_gobject) \
+		$(use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable qt4 liblightdm_qt) || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	pamd_mimic system-local-login lightdm auth account session || die
+
+	find "${ED}" -name '*.la' -exec rm {} + || die
+
+	dodoc AUTHORS ChangeLog NEWS README || die
+}