freerdp from gentoo

3 files changed, 115 insertions, 0 deletions

diff --git a/net-misc/freerdp/Manifest b/net-misc/freerdp/Manifest
new file mode 100644
index 0000000..8f72467
--- /dev/null
+++ b/net-misc/freerdp/Manifest
@@ -0,0 +1,3 @@
+DIST freerdp-1.1.0_beta1_p20130710.tar.gz 6682149 SHA256 0d0d2eec7e78b61458415ee98ad54379b31e9fc269b8bacf3e939bd048ac5e61 SHA512 89ec08acff5c9bbafe107cd079005146b6c4447fbe3172d8f774a20ab6b5e1f24abdeab2d7cb0d7694251aaea2924b0a10f1c0b4b660994cdfa51e8428b90440 WHIRLPOOL 2f7c04bde54293fc8fc85ba03baf7dc64e5da4cecdc87aaaa2ff316127abc43f0b56d70e14652f97f2e97a8f43bee8880837a94230448397dfad5f4ddbd055b1
+EBUILD freerdp-1.1.0_beta1_p20130710.ebuild 2531 SHA256 1699642570d3bea0172336efc2f1ad14118de3706119098dcc374e8d36e56dfd SHA512 9fef8fa8c8f92289b89d9982dead8544c5f79a4c5472e0ea80c4ad69c49a04220d1f093b32664b1869b4a13fb93c1488683524d604896d659be25849749b86a8 WHIRLPOOL 35d735c0cd96ea59252d9ec3933d9f76f2b5f98f002647a1c34f895638e1f678912e8c29eea56de4f6a15a514ea7d121d93b4011b5879816ecc0ebb621317259
+MISC metadata.xml 410 SHA256 a72feebca542632c8bf273df04b6e734c369d69e76bcdc4b2b7ad2896e0da3fd SHA512 1f47833a84fa53b694ae3ddc20c7bcd4fe9fca22cd51f1e670a744060ffa629cf03250b9bfde02539ed82a4bda409171b4f19bb9a10ae4ef9ebe05723dc33978 WHIRLPOOL f3a15d853f73840ef736aebc0f40a4318527260912912667869788596384fd8a840d063b817621af01b209646dc4b5b5cef37ce8bb4a9c5d8b716a1977c59056
diff --git a/net-misc/freerdp/freerdp-1.1.0_beta1_p20130710.ebuild b/net-misc/freerdp/freerdp-1.1.0_beta1_p20130710.ebuild
new file mode 100644
index 0000000..cca0115
--- /dev/null
+++ b/net-misc/freerdp/freerdp-1.1.0_beta1_p20130710.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-1.1.0_beta1_p20130710.ebuild,v 1.3 2013/11/11 16:32:17 floppym Exp $
+
+EAPI="5"
+
+inherit cmake-utils vcs-snapshot
+
+if [[ ${PV} != 9999* ]]; then
+	COMMIT="780d451afad21a22d2af6bd030ee71311856f038"
+	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+else
+	inherit git-2
+	SRC_URI=""
+	EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
+		https://github.com/FreeRDP/FreeRDP.git"
+	KEYWORDS=""
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="alsa +channels +client cups debug directfb doc ffmpeg gstreamer jpeg
+	pulseaudio server smartcard sse2 test X xinerama xv"
+
+RDEPEND="
+	dev-libs/openssl
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	client? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			xinerama? ( x11-libs/libXinerama )
+			xv? ( x11-libs/libXv )
+		)
+	)
+	directfb? ( dev-libs/DirectFB )
+	ffmpeg? ( virtual/ffmpeg )
+	gstreamer? (
+		media-libs/gstreamer:0.10
+		media-libs/gst-plugins-base:0.10
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}
+	client? ( X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) ) )
+"
+
+DOCS=( README )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with alsa ALSA)
+		$(cmake-utils_use_with channels CHANNELS)
+		$(cmake-utils_use_with client CLIENT)
+		$(cmake-utils_use_with cups CUPS)
+		$(cmake-utils_use_with debug DEBUG_ALL)
+		$(cmake-utils_use_with doc MANPAGES)
+		$(cmake-utils_use_with directfb DIRECTFB)
+		$(cmake-utils_use_with ffmpeg FFMPEG)
+		$(cmake-utils_use_with gstreamer GSTREAMER)
+		$(cmake-utils_use_with jpeg JPEG)
+		$(cmake-utils_use_with pulseaudio PULSEAUDIO)
+		$(cmake-utils_use_with server SERVER)
+		$(cmake-utils_use_with smartcard PCSC)
+		$(cmake-utils_use_with sse2 SSE2)
+		$(cmake-utils_use_with X X11)
+		$(cmake-utils_use_with xinerama XINERAMA)
+		$(cmake-utils_use_with xv XV)
+		$(cmake-utils_use_build test TESTING)
+	)
+	cmake-utils_src_configure
+}
diff --git a/net-misc/freerdp/metadata.xml b/net-misc/freerdp/metadata.xml
new file mode 100644
index 0000000..bcfaa33
--- /dev/null
+++ b/net-misc/freerdp/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer>
+		<email>floppym@gentoo.org</email>
+		<name>Mike Gilbert</name>
+	</maintainer>
+	<use>
+		<flag name="channels">Build virtual channel plugins</flag>
+		<flag name="client">Build client binaries</flag>
+		<flag name="server">Build server binaries</flag>
+	</use>
+</pkgmetadata>