dev-python/graph-tool: bump to 2.71

Signed-off-by: Gerion Entrup <gerion.entrup@flump.de>

3 files changed, 98 insertions, 0 deletions

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
new file mode 100644
index 0000000..5140f24
--- /dev/null
+++ b/dev-python/graph-tool/Manifest
@@ -0,0 +1,3 @@
+DIST graph-tool-2.71.tar.xz 14997876 BLAKE2B c23b4729065ebba43ba3501bca63980a40354e2ff6727ea3b663c60521cdf571ab794eb83f9cfb56909d92e3be90ac5d94c7dcd7f6639cb2c2fb9ee5c675697f SHA512 caedba222e499b81d93d51097c526a8a64dd1f3b91141012c67ffe40532f6168294e430887484522f75709828d280f95cc75bc400a886e71bf73d64efd9b7833
+EBUILD graph-tool-2.71.ebuild 1778 BLAKE2B 7249b7e5d6ffbccf5967287ccf3e5ccd24b6e90300485ca623e99bb91e01c8f5316901c01d7b90b0d5468d41331dd73b2503c1339362fe19185eb31bf9cf2ee8 SHA512 75f70b1688eac59bbfadc826c70808bcb9325b23d8c7eae16b6cddffbc66ee372b48e3b96ac41d6d093fd76f0503b7774f2457e4b65a133a393c05ad99ffa9e0
+MISC metadata.xml 318 BLAKE2B f5a87067223b56a1c2f2a89278b2b7b8ab612a1575264999e40a3bb34853cf603a7a11546c7ff9aa4f253beeb09c2fd26abc8fda1c6f2de5bda35069e9f932bc SHA512 b3bf8fc36dd5ae8e8b773cf9a0670fa1c6a2ee3730c9f2980abf5823f52879c5ef87a357c25d025896bd75ced32ffcec82ecdb1f080babc4fe13d2a2b70624b1
diff --git a/dev-python/graph-tool/graph-tool-2.71.ebuild b/dev-python/graph-tool/graph-tool-2.71.ebuild
new file mode 100644
index 0000000..933f090
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.71.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/boost:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal:=
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	cairo? (
+		dev-cpp/cairomm:0
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		x11-libs/cairo[X]
+	)"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	my_configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="boost_${EPYTHON/./}"
+	}
+	python_foreach_impl run_in_build_dir my_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir emake
+}
+
+src_install() {
+	my_python_install() {
+		default
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir my_python_install
+
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/dev-python/graph-tool/metadata.xml b/dev-python/graph-tool/metadata.xml
new file mode 100644
index 0000000..991e9cc
--- /dev/null
+++ b/dev-python/graph-tool/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>gerion.entrup@flump.de</email>
+		<name>Gerion Entrup</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">graph-tool</remote-id>
+	</upstream>
+</pkgmetadata>