blob: a7e8f1c35a3ee9254bc1ed5ceb5a223e64ab8279 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake linux-info systemd tmpfiles
DESCRIPTION="Simple Desktop Display Manager"
HOMEPAGE="https://github.com/sddm/sddm"
SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.xz"
LICENSE="GPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0 public-domain"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="+elogind +pam systemd test"
REQUIRED_USE="?? ( elogind systemd )"
RESTRICT="!test? ( test )"
COMMON_DEPEND="
acct-group/sddm
acct-user/sddm
dev-qt/qtcore:5
dev-qt/qtdbus:5
dev-qt/qtdeclarative:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
x11-base/xorg-server
x11-libs/libxcb[xkb]
elogind? ( sys-auth/elogind )
pam? ( sys-libs/pam )
!pam? ( virtual/libcrypt:= )
systemd? ( sys-apps/systemd:= )
!systemd? ( sys-power/upower )
"
DEPEND="${COMMON_DEPEND}
test? ( dev-qt/qttest:5 )
"
RDEPEND="${COMMON_DEPEND}
!systemd? ( gui-libs/display-manager-init )
"
BDEPEND="
dev-python/docutils
dev-qt/linguist-tools:5
kde-frameworks/extra-cmake-modules:5
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}/${P}-respect-user-flags.patch"
"${FILESDIR}/${P}-Xsession.patch" # bug 611210
"${FILESDIR}/${PN}-0.18.0-sddmconfdir.patch"
# fix for groups: https://github.com/sddm/sddm/issues/1159
"${FILESDIR}/${P}-revert-honor-PAM-supplemental-groups.patch"
"${FILESDIR}/${P}-honor-PAM-supplemental-groups-v2.patch"
# fix for ReuseSession=true
"${FILESDIR}/${P}-only-reuse-online-sessions.patch"
# TODO: fix properly
"${FILESDIR}/pam-1.4-substack.patch"
# upstream git develop branch:
"${FILESDIR}/${P}-qt-5.15.2.patch"
"${FILESDIR}/${P}-cve-2020-28049.patch" # bug 753104
"${FILESDIR}/${P}-nvidia-glitches-vt-switch.patch"
"${FILESDIR}/${P}-drop-wayland-suffix.patch"
"${FILESDIR}/${P}-fix-qt-5.15.7.patch" # KDE-bug 458865
)
pkg_setup() {
local CONFIG_CHECK="~DRM"
use kernel_linux && linux-info_pkg_setup
}
src_prepare() {
cmake_src_prepare
if ! use test; then
sed -e "/^find_package/s/ Test//" -i CMakeLists.txt || die
cmake_comment_add_subdirectory test
fi
}
src_configure() {
local mycmakeargs=(
-DENABLE_PAM=$(usex pam)
-DNO_SYSTEMD=$(usex '!systemd')
-DUSE_ELOGIND=$(usex 'elogind')
-DBUILD_MAN_PAGES=ON
-DDBUS_CONFIG_FILENAME="org.freedesktop.sddm.conf"
)
cmake_src_configure
}
src_install() {
cmake_src_install
newtmpfiles "${FILESDIR}/${PN}.tmpfiles" "${PN}.conf"
# Create a default.conf as upstream dropped /etc/sddm.conf w/o replacement
local confd="/usr/share/sddm/sddm.conf.d"
dodir ${confd}
"${D}"/usr/bin/sddm --example-config > "${D}/${confd}"/00default.conf \
|| die "Failed to create 00default.conf"
sed -e "/^InputMethod/s/qtvirtualkeyboard//" \
-e "/^ReuseSession/s/false/true/" \
-e "/^EnableHiDPI/s/false/true/" \
-i "${D}/${confd}"/00default.conf || die
}
pkg_postinst() {
tmpfiles_process "${PN}.conf"
elog "Starting with 0.18.0, SDDM no longer installs /etc/sddm.conf"
elog "Use it to override specific options. SDDM defaults are now"
elog "found in: /usr/share/sddm/sddm.conf.d/00default.conf"
elog
elog "NOTE: If SDDM startup appears to hang then entropy pool is too low."
elog "This can be fixed by configuring one of the following:"
elog " - Enable CONFIG_RANDOM_TRUST_CPU in linux kernel"
elog " - # emerge sys-apps/haveged && rc-update add haveged boot"
elog " - # emerge sys-apps/rng-tools && rc-update add rngd boot"
elog
elog "For more information on how to configure SDDM, please visit the wiki:"
elog " https://wiki.gentoo.org/wiki/SDDM"
if has_version x11-drivers/nvidia-drivers; then
elog
elog " Nvidia GPU owners in particular should pay attention"
elog " to the troubleshooting section."
fi
systemd_reenable sddm.service
}
|
GitWeb