blob: a671662a7e34c1ecda14b65a535463f0c7193ab5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools xdg-utils
DESCRIPTION="LightDM GTK+ Greeter"
HOMEPAGE="https://github.com/Xubuntu/lightdm-gtk-greeter"
SRC_URI="https://github.com/Xubuntu/${PN}/releases/download/${P}/${P}.tar.gz
branding? ( https://dev.gentoo.org/~polynomial-c/dist/lightdm-gentoo-patch-2.tar.gz )"
LICENSE="GPL-3 LGPL-3
branding? ( CC-BY-3.0 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 x86"
IUSE="appindicator branding"
DEPEND="appindicator? ( dev-libs/libindicator:3 )
x11-libs/gtk+:3
>=x11-misc/lightdm-1.2.2"
BDEPEND="
dev-util/intltool
dev-util/xfce4-dev-tools
sys-devel/gettext
"
RDEPEND="${DEPEND}
x11-themes/gnome-themes-standard
>=x11-themes/adwaita-icon-theme-3.14.1"
GENTOO_BG="gentoo-bg_65.jpg"
src_prepare() {
# Ok, this has to be fixed in the tarball but I am too lazy to do it.
# I will fix this once I decide to update the tarball with a new gentoo
# background
# Bug #404467
if use branding; then
sed \
-e "/xft-hintstyle/s:slight:hintslight:" \
-e "/background/s:=.*:=/usr/share/lightdm/backgrounds/${GENTOO_BG}:" \
-i "${WORKDIR}"/${PN}.conf || die
# Add back the reboot/shutdown buttons
echo 'indicators=~host;~spacer;~clock;~spacer;~session;~language;~a11y;~power;~' \
>> "${WORKDIR}"/${PN}.conf || die
fi
default
# Fix docdir
sed "/^docdir/s@${PN}@${PF}@" -i data/Makefile.am || die
eautoreconf
}
src_configure() {
local myeconfargs=(
--enable-kill-on-sigterm
--enable-at-spi-command="${EPREFIX}/usr/libexec/at-spi-bus-launcher --launch-immediately"
$(use_enable appindicator libindicator)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
if use branding; then
insinto /etc/lightdm/
doins "${WORKDIR}"/${PN}.conf
insinto /usr/share/lightdm/backgrounds/
doins "${WORKDIR}"/${GENTOO_BG}
newdoc "${WORKDIR}"/README.txt README-background.txt
fi
}
pkg_postinst() {
xdg_icon_cache_update
}
pkg_postrm() {
xdg_icon_cache_update
}
|
GitWeb