blob: 536afa2850687e57b1d0589269a4be94fbc7b105 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson pam
DESCRIPTION="OpenRC fork with user services support"
HOMEPAGE="https://github.com/navi-desu/openrc/"
if [[ ${PV} =~ ^9{4,}$ ]]; then
EGIT_REPO_URI="https://github.com/navi-desu/openrc.git"
inherit git-r3
else
SRC_URI="https://github.com/navi-desu/openrc/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
S="${WORKDIR}/openrc-${PV/_/-}"
fi
LICENSE="BSD-2"
SLOT="0"
IUSE="audit bash caps debug pam newnet +netifrc selinux s6 +sysvinit sysv-utils unicode"
COMMON_DEPEND="
pam? ( sys-libs/pam )
audit? ( sys-process/audit )
caps? ( sys-libs/libcap )
sys-process/psmisc
selinux? (
sys-apps/policycoreutils
>=sys-libs/libselinux-2.6
)"
DEPEND="${COMMON_DEPEND}
virtual/os-headers"
RDEPEND="${COMMON_DEPEND}
!sys-apps/openrc
bash? ( app-shells/bash )
sysv-utils? (
!sys-apps/systemd[sysv-utils(-)]
!sys-apps/sysvinit
)
!sysv-utils? (
sysvinit? ( >=sys-apps/sysvinit-2.86-r6[selinux?] )
s6? ( sys-apps/s6-linux-init[sysv-utils(-)] )
)
virtual/tmpfiles
selinux? (
>=sec-policy/selinux-base-policy-2.20170204-r4
>=sec-policy/selinux-openrc-2.20170204-r4
)
"
PDEPEND="netifrc? ( net-misc/netifrc )"
src_configure() {
local emesonargs=(
$(meson_feature audit)
"-Dbranding=\"Gentoo Linux\""
$(meson_feature caps capabilities)
$(meson_use newnet)
-Dos=Linux
$(meson_use pam)
$(meson_feature selinux)
-Drootprefix="${EPREFIX}"
-Dshell=$(usex bash /bin/bash /bin/sh)
$(meson_use sysv-utils sysvinit)
)
# export DEBUG=$(usev debug)
meson_src_configure
}
# set_config <file> <option name> <yes value> <no value> test
# a value of "#" will just comment out the option
set_config() {
local file="${ED}/$1" var=$2 val com
eval "${@:5}" && val=$3 || val=$4
[[ ${val} == "#" ]] && com="#" && val='\2'
sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
}
set_config_yes_no() {
set_config "$1" "$2" YES NO "${@:3}"
}
src_install() {
meson_install
keepdir /lib/rc/tmp
# Setup unicode defaults for silly unicode users
set_config_yes_no /etc/rc.conf unicode use unicode
# Cater to the norm
set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'
# On HPPA, do not run consolefont by default (bug #222889)
if use hppa; then
rm -f "${ED}"/etc/runlevels/boot/consolefont
fi
# Support for logfile rotation
insinto /etc/logrotate.d
newins "${FILESDIR}"/openrc.logrotate openrc
if use pam; then
# install gentoo pam.d files
newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
newpamd "${FILESDIR}"/start-stop-daemon.pam supervise-daemon
fi
# install documentation
dodoc *.md
}
pkg_preinst() {
# avoid default thrashing in conf.d files when possible #295406
if [[ -e "${EROOT}"/etc/conf.d/hostname ]] ; then
(
unset hostname HOSTNAME
source "${EROOT}"/etc/conf.d/hostname
: ${hostname:=${HOSTNAME}}
[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
)
fi
# set default interactive shell to sulogin if it exists
set_config /etc/rc.conf rc_shell /sbin/sulogin "#" test -e /sbin/sulogin
return 0
}
pkg_postinst() {
if use hppa; then
elog "Setting the console font does not work on all HPPA consoles."
elog "You can still enable it by running:"
elog "# rc-update add consolefont boot"
fi
if ! use newnet && ! use netifrc; then
ewarn "You have emerged OpenRc without network support. This"
ewarn "means you need to SET UP a network manager such as"
ewarn " net-misc/netifrc, net-misc/dhcpcd, net-misc/connman,"
ewarn " net-misc/NetworkManager, or net-vpn/badvpn."
ewarn "Or, you have the option of emerging openrc with the newnet"
ewarn "use flag and configuring /etc/conf.d/network and"
ewarn "/etc/conf.d/staticroute if you only use static interfaces."
ewarn
fi
if use newnet && [ ! -e "${EROOT}"/etc/runlevels/boot/network ]; then
ewarn "Please add the network service to your boot runlevel"
ewarn "as soon as possible. Not doing so could leave you with a system"
ewarn "without networking."
ewarn
fi
if [[ -z ${REPLACING_VERSIONS} ]]; then
ewarn "To support starting user services automatically, please append"
ewarn "'-session optional pam_openrc.so' to /etc/pam.d/system-login"
ewarn
fi
}
|
GitWeb