blob: 72a23985077c05c0e34b27380c2f1d4ac7fa6255 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MAJOR=$(ver_cut 1)
CMAKE_IN_SOURCE_BUILD="ON"
inherit flag-o-matic cmake readme.gentoo-r1
DESCRIPTION="The Lean Theorem Prover"
HOMEPAGE="https://leanprover-community.github.io/"
if [[ ${PV} == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/leanprover-community/lean.git"
else
SRC_URI="https://github.com/leanprover-community/lean/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
S="${S}/src"
LICENSE="Apache-2.0"
SLOT="0/${MAJOR}"
IUSE="debug +threads"
RDEPEND="dev-libs/gmp:="
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}"/${PN}-3.50.3-gcc-13.patch
"${FILESDIR}"/${PN}-CMakeLists-fix_flags.patch
)
src_configure() {
local CMAKE_BUILD_TYPE
if use debug; then
CMAKE_BUILD_TYPE="Debug"
else
CMAKE_BUILD_TYPE="Release"
fi
filter-lto
local -a mycmakeargs=(
-DALPHA=ON
-DAUTO_THREAD_FINALIZATION=ON
-DJSON=ON # bug 833900
-DLEAN_EXTRA_CXX_FLAGS="${CXXFLAGS}"
-DMULTI_THREAD=$(usex threads)
-DUSE_GITHASH=OFF
)
cmake_src_configure
}
src_test() {
local -a myctestargs=(
# Disable problematic "style_check" cpplint test,
# this also removes the python test dependency
--exclude-regex style_check
)
cmake_src_test
}
src_install() {
cmake_src_install
local DISABLE_AUTOFORMATTING="yes"
local DOC_CONTENTS="You probably want to use lean with mathlib, you can either:
- Do not install mathlib globally and use local versions
- Use leanproject from sci-mathematics/mathlib-tools
$ leanproject global-install
- Use leanpkg and compile mathlib (which will take some time)
$ leanpkg install https://github.com/leanprover-community/mathlib"
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_print_elog
}
|
GitWeb