sci-libs/libccd/libccd-2.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

SCM=""
if [ "${PV#9999}" != "${PV}" ] ; then
	SCM="git-r3"
	EGIT_REPO_URI="http://github.com/danfis/libccd"
fi

inherit ${SCM} cmake-utils toolchain-funcs

if [ "${PV#9999}" != "${PV}" ] ; then
	KEYWORDS=""
	SRC_URI=""
else
	KEYWORDS="~amd64 ~arm"
	SRC_URI="http://libccd.danfis.cz/files/${P}.tar.gz"
fi

DESCRIPTION="Library for collision detection between two convex shapes"
HOMEPAGE="http://libccd.danfis.cz/"
LICENSE="BSD"
SLOT="0"
IUSE="double doc"

RDEPEND=""
DEPEND="${RDEPEND}
	doc? ( dev-python/sphinx )"
DOCS=( README )

src_configure() {
	local mycmakeargs=(
		"-DCCD_DOUBLE=$(usex double TRUE FALSE)"
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	if use doc ; then
		cd "${S}/doc"
		emake SPHINXBUILD=sphinx-build html
	fi
}

src_test() {
	cd src/testsuites
	tc-export CC
	LDFLAGS="-L${BUILD_DIR} ${LDFLAGS}" \
	LD_LIBRARY_PATH="${BUILD_DIR}:${LD_LIBRARY_PATH}" \
		emake check
}

src_install() {
	cmake-utils_src_install
	use doc && dohtml -r "${S}/doc/_build/html/"*
}