blob: 72a6f7164ec9c3a8b53f62ab4557c53107c1c4a5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
# Tests fail with pypy
PYTHON_COMPAT=( pypy3 python3_{6,7,8,9} )
inherit distutils-r1
MY_PN="${PN/-/.}"
DESCRIPTION="Classes used by other projects by developer jaraco"
HOMEPAGE="https://github.com/jaraco/jaraco.classes"
SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc x86"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/namespace-jaraco-2[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
"
DEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
test? (
${RDEPEND}
>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
)
"
S="${WORKDIR}/${MY_PN}-${PV}"
distutils_enable_sphinx docs \
">=dev-python/jaraco-packaging-3.2" \
">=dev-python/rst-linker-1.9"
python_prepare_all() {
# avoid a setuptools_scm dependency
sed -i "s:use_scm_version=True:version='${PV}':" setup.py || die
sed -r -i "s:setuptools_scm[[:space:]]*([><=]{1,2}[[:space:]]*[0-9.a-zA-Z]+)[[:space:]]*::" \
setup.cfg || die
distutils-r1_python_prepare_all
}
python_test() {
# Avoid ImportMismatchError, override pytest options to skip flake8
pytest -vv "${BUILD_DIR}"/lib --override-ini="addopts=--doctest-modules" \
|| die "tests failed with ${EPYTHON}"
}
# https://wiki.gentoo.org/wiki/Project:Python/Namespace_packages#File_collisions_between_pkgutil-style_packages
python_install() {
rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
# note: eclass may default to --skip-build in the future
distutils-r1_python_install --skip-build
}
|
GitWeb
