blob: e6dabf07cdbd19ec45e80dc57ee0968c1e8171c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} )
inherit distutils-r1
DESCRIPTION="Python (ctypes) bindings for SDL2 libraries"
HOMEPAGE="
https://github.com/py-sdl/py-sdl2/
https://pypi.org/project/PySDL2/
"
SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
LICENSE="|| ( public-domain CC0-1.0 ZLIB )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# Optional deps:
# - dev-python/numpy,
# - dev-python/pillow,
# - media-libs/sdl2-* (loaded dynamically via ctypes).
#
# If a reverse dependency needs the specific module, it should
# explicitly depend on the optional module in question. You also
# probably need to explicitly require some media-libs/libsdl2 flags.
RDEPEND="media-libs/libsdl2"
# Require all of SDL2 libraries and at least the most common subsystems
# for better test coverage.
DEPEND="
test? (
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
media-libs/libsdl2[joystick,sound,video]
media-libs/sdl2-gfx
media-libs/sdl2-image[gif,jpeg,png,tiff,webp]
|| (
media-libs/sdl2-mixer[flac]
media-libs/sdl2-mixer[midi]
media-libs/sdl2-mixer[mod]
media-libs/sdl2-mixer[mp3]
media-libs/sdl2-mixer[opus]
)
media-libs/sdl2-ttf
)"
EPYTEST_DESELECT=(
# Both tests fail and seem machine-dependent?
sdl2/test/sdlttf_test.py::test_TTF_SetFontSize
sdl2/test/sdlttf_test.py::test_TTF_SetFontSizeDPI
)
distutils_enable_tests pytest
src_test() {
# from .travis.yml
local -x SDL_VIDEODRIVER=dummy
local -x SDL_AUDIODRIVER=dummy
local -x SDL_RENDER_DRIVER=software
distutils-r1_src_test
}
|
GitWeb
