blob: a0ecf007427a1a81280ab1095c30abe61c91f595 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
MY_PN="${PN/PEAR-/}"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="A full-featured command-line options and arguments parser"
HOMEPAGE="https://pear.php.net/package/Console_CommandLine"
SRC_URI="http://download.pear.php.net/package/${MY_P}.tgz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 arm hppa ia64 ppc ppc64 sparc x86"
IUSE="examples test"
RESTRICT="!test? ( test )"
# Only needs PEAR_Exception (not yet packaged) -- not all of PEAR-PEAR.
RDEPEND="dev-lang/php:*
dev-php/PEAR-PEAR"
# Beware, the test suite really needs PEAR-PEAR.
DEPEND="test? ( ${RDEPEND} )"
S="${WORKDIR}/${MY_P}"
src_prepare() {
# There's one occurrence of @data_dir@ that needs to be replaced
# This location just has to agree with where we put the "data"
# directory during src_install().
default
sed -i "s|@data_dir@|${EPREFIX}/usr/share|" \
Console/CommandLine/XmlParser.php || die
}
src_install() {
use examples && dodoc -r docs/examples
insinto "/usr/share/${MY_PN}"
doins -r data
insinto /usr/share/php
doins -r Console
}
src_test() {
# Requires the "pear" executable from dev-php/PEAR-PEAR.
pear run-tests tests || die
# The command succeeds regardless of whether or not the test suite
# passed, but this file is only written when there was a failure.
[[ -f run-tests.log ]] && die "test suite failed"
}
|
GitWeb
