blob: 4171ba58ee19d5585c0acfdd5de2cd342f1135f4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit libtool multilib-minimal verify-sig
MY_P="${P}-stable"
DESCRIPTION="Library to execute a function when a specific event occurs on a file descriptor"
HOMEPAGE="
https://libevent.org/
https://github.com/libevent/libevent/
"
BASE_URI="https://github.com/libevent/libevent/releases/download/release-${MY_P#*-}"
SRC_URI="
${BASE_URI}/${MY_P}.tar.gz
verify-sig? (
${BASE_URI}/${MY_P}.tar.gz.asc
)
"
S=${WORKDIR}/${MY_P}
LICENSE="BSD"
SLOT="0/2.1-7"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="
+clock-gettime debug malloc-replacement +ssl static-libs test
verbose-debug
"
RESTRICT="!test? ( test )"
DEPEND="
ssl? (
>=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}]
)
"
RDEPEND="
${DEPEND}
!<=dev-libs/9libs-1.0
"
BDEPEND="
verify-sig? (
sec-keys/openpgp-keys-libevent
)
"
MULTILIB_WRAPPED_HEADERS=(
/usr/include/event2/event-config.h
)
PATCHES=(
"${FILESDIR}"/${P}-clang16.patch #880381
"${FILESDIR}"/${P}-libressl.patch #903001
)
VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/libevent.asc
src_prepare() {
default
# bug #767472
elibtoolize
}
multilib_src_configure() {
# fix out-of-source builds
mkdir -p test || die
ECONF_SOURCE="${S}" \
econf \
$(use_enable clock-gettime) \
$(use_enable debug debug-mode) \
$(use_enable malloc-replacement malloc-replacement) \
$(use_enable ssl openssl) \
$(use_enable static-libs static) \
$(use_enable test libevent-regress) \
$(use_enable verbose-debug) \
--disable-samples
}
src_test() {
# The test suite doesn't quite work (see bug #406801 for the latest
# installment in a riveting series of reports).
:
# emake -C test check | tee "${T}"/tests
}
DOCS=( ChangeLog{,-1.4,-2.0} )
multilib_src_install_all() {
einstalldocs
find "${ED}" -name '*.la' -delete || die
}
|
GitWeb