blob: 1c85353f16ee842346fd40a2087a1c14f5101326 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools toolchain-funcs flag-o-matic
MY_PV="${PV/_/-}"
MY_P="util-linux-${MY_PV}"
LOOPAES_P="loop-AES-v3.7q"
S="${WORKDIR}/${MY_P}"
DESCRIPTION="Loop-AES losetup utility"
HOMEPAGE="https://www.kernel.org/pub/linux/utils/util-linux/"
SRC_URI="https://www.kernel.org/pub/linux/utils/util-linux/v${PV:0:4}/${MY_P}.tar.xz
http://loop-aes.sourceforge.net/loop-AES/${LOOPAES_P}.tar.bz2"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86"
LICENSE="GPL-2 LGPL-2.1 BSD-4 MIT public-domain"
SLOT="0"
IUSE="nls selinux static"
RDEPEND="selinux? ( >=sys-libs/libselinux-2.2.2-r4 )"
BDEPEND="
virtual/pkgconfig
nls? ( sys-devel/gettext )
"
DEPEND="
${RDEPEND}
virtual/os-headers
"
PATCHES=(
"${WORKDIR}/${LOOPAES_P}/util-linux-${PV}.diff"
)
src_prepare() {
default
eautoreconf
}
lfs_fallocate_test() {
# Make sure we can use fallocate with LFS #300307
cat <<-EOF > "${T}"/fallocate.${ABI}.c || die
#define _GNU_SOURCE
#include <fcntl.h>
main() { return fallocate(0, 0, 0, 0); }
EOF
append-lfs-flags
$( $(tc-getCC) ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} "${T}"/fallocate.${ABI}.c -o /dev/null >/dev/null 2>&1 || die) \
|| export ac_cv_func_fallocate=no
rm "${T}"/fallocate.${ABI}.c || die
}
src_configure() {
lfs_fallocate_test
# The scanf test in a run-time test which fails while cross-compiling.
# Blindly assume a POSIX setup since we require libmount, and libmount
# itself fails when the scanf test fails. #531856
tc-is-cross-compiler && export scanf_cv_alloc_modifier=ms
ECONF_SOURCE=${S} \
econf \
--disable-all-programs \
--disable-pylibmount \
--enable-libsmartcols \
--enable-losetup \
--without-ncurses \
--without-udev \
$(use_enable nls) \
$(use_with selinux) \
$(tc-has-tls || echo --disable-tls) \
$(use static && echo --enable-static-programs=losetup)
}
src_install() {
emake install DESTDIR="${T}/root"
newsbin "${T}/root/sbin/losetup" loop-aes-losetup
newman "${T}/root/usr/share/man/man8/losetup.8" loop-aes-losetup.8
use static && newsbin "${T}/root/bin/losetup.static" loop-aes-losetup.static
}
|
GitWeb