app-arch/bzip3/bzip3-1.1.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs autotools

DESCRIPTION="A better and stronger spiritual successor to BZip2"
HOMEPAGE="https://github.com/kspalaiologos/bzip3"

if [[ ${PV} == *9999* ]] ; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/kspalaiologos/${PN}.git"
else
	SRC_URI="https://github.com/kspalaiologos/${PN}/releases/download/${PV}/${P}.tar.xz"
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="LGPL-3+"
SLOT="0"
IUSE="static-libs"

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	# ./configure script will default to Clang if it is found on the system,
	# force the use of CC selected by the user with CC=$(tc-getCC)
	econf $(use_enable static-libs static) CC=$(tc-getCC)
}

src_install() {
	default

	if ! use static-libs ; then
		find "${ED}" -type f -name '*.la' -delete || die
	fi
}