1 files changed, 57 insertions, 0 deletions
diff --git a/sci-libs/coinor-bcps/coinor-bcps-0.93.10.ebuild b/sci-libs/coinor-bcps/coinor-bcps-0.93.10.ebuild
new file mode 100644
index 000000000000..0c509c19d105
--- /dev/null
+++ b/sci-libs/coinor-bcps/coinor-bcps-0.93.10.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools-utils multilib
+
+MYPN=Bcps
+
+DESCRIPTION="COIN-OR BiCEPS data handling library"
+HOMEPAGE="https://projects.coin-or.org/CHiPPS/"
+SRC_URI="http://www.coin-or.org/download/source/${MYPN}/${MYPN}-${PV}.tgz"
+
+LICENSE="CPL-1.0"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples static-libs test"
+
+RDEPEND="
+	sci-libs/coinor-utils:=
+	sci-libs/coinor-clp:=
+	sci-libs/coinor-alps:="
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( sci-libs/coinor-sample )"
+
+S="${WORKDIR}/${MYPN}-${PV}/${MYPN}"
+
+src_prepare() {
+	# needed for the --with-coin-instdir
+	dodir /usr
+	sed -i \
+		-e "s:lib/pkgconfig:$(get_libdir)/pkgconfig:g" \
+		configure || die
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-dependency-linking
+		--with-coin-instdir="${ED}"/usr
+	)
+	autotools-utils_src_configure
+}
+
+src_test() {
+	autotools-utils_src_test test
+}
+
+src_install() {
+	autotools-utils_src_install
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}