1 files changed, 55 insertions, 0 deletions
diff --git a/net-mail/offlineimap/offlineimap-7.3.3.ebuild b/net-mail/offlineimap/offlineimap-7.3.3.ebuild
new file mode 100644
index 000000000000..fb8580cca932
--- /dev/null
+++ b/net-mail/offlineimap/offlineimap-7.3.3.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_STEUPTOOLS=no
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads,sqlite,ssl?"
+
+inherit distutils-r1
+
+DESCRIPTION="Powerful IMAP/Maildir synchronization and reader support"
+HOMEPAGE="https://www.offlineimap.org/ https://github.com/offlineimap/offlineimap"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ssl"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/six[${PYTHON_USEDEP}]
+	')"
+DEPEND="doc? ( app-text/asciidoc )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-7.0.3-darwin10.patch"
+	"${FILESDIR}/${PN}-norfc6555.patch"
+)
+
+src_compile() {
+	distutils-r1_src_compile
+	use doc && emake -C docs man
+}
+
+src_install() {
+	distutils-r1_src_install
+	dodoc offlineimap.conf offlineimap.conf.minimal
+	use doc && doman docs/{offlineimap.1,offlineimapui.7}
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "You will need to configure offlineimap by creating ~/.offlineimaprc"
+		elog "Sample configurations are in /usr/share/doc/${PF}/"
+		elog ""
+		elog "If you connect via ssl/tls and don't use CA cert checking, it will"
+		elog "display the server's cert fingerprint and require you to add it to the"
+		elog "configuration file to be sure it connects to the same server every"
+		elog "time. This serves to help fixing CVE-2010-4532 (offlineimap doesn't"
+		elog "check SSL server certificate) in cases where you have no CA cert."
+	fi
+}