1 files changed, 52 insertions, 0 deletions
diff --git a/dev-util/drone/drone-0.8.0_rc4.ebuild b/dev-util/drone/drone-0.8.0_rc4.ebuild
new file mode 100644
index 000000000000..414020cd3e59
--- /dev/null
+++ b/dev-util/drone/drone-0.8.0_rc4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGO_PN="github.com/drone/drone"
+EGIT_COMMIT="1e64f61009f2e57bd5be41d504ca41305b2263bb"
+EGO_VENDOR=( "github.com/drone/drone-ui 73adc4cc5cee2e715caf508a5473965287448712"
+	"github.com/golang/protobuf 17ce1425424ab154092bbb43af630bd647f3bb0d"
+	"golang.org/x/net 66aacef3dd8a676686c7ae3716979581e8b03c47 github.com/golang/net"
+	)
+
+inherit golang-build golang-vcs-snapshot user
+
+ARCHIVE_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="A Continuous Delivery platform built on Docker, written in Go"
+HOMEPAGE="https://github.com/drone/drone"
+SRC_URI="${ARCHIVE_URI}
+	${EGO_VENDOR_URI}"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-go/go-bindata
+	dev-go/go-bindata-assetfs:="
+
+RESTRICT="test"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/drone ${PN}
+}
+
+src_compile() {
+	pushd src || die
+	GOPATH="${WORKDIR}/${P}:$(get_golibdir_gopath)" go build -ldflags "-extldflags '-static' -X github.com/drone/drone/version.VersionDev=build.${PV}.${EGIT_COMMIT:0:7}" -o release/drone-server ${EGO_PN}/cmd/drone-server || die
+	GOPATH="${WORKDIR}/${P}" go build -ldflags "-X github.com/drone/drone/version.VersionDev=build.${PV}.${EGIT_COMMIT:0:7}" -o release/drone-agent ${EGO_PN}/cmd/drone-agent || die
+	popd || die
+}
+
+src_install() {
+	dobin src/release/drone-{agent,server}
+	dodoc src/github.com/drone/drone/README.md
+	keepdir /var/log/drone /var/lib/drone
+	fowners -R ${PN}:${PN} /var/log/drone /var/lib/drone
+	newinitd "${FILESDIR}"/drone-server.initd drone-server
+	newconfd "${FILESDIR}"/drone-server.confd drone-server
+	newinitd "${FILESDIR}"/drone-agent.initd drone-agent
+	newconfd "${FILESDIR}"/drone-agent.confd drone-agent
+}