1 files changed, 44 insertions, 0 deletions
diff --git a/dev-python/pyro5/pyro5-5.15-r1.ebuild b/dev-python/pyro5/pyro5-5.15-r1.ebuild
new file mode 100644
index 000000000000..2a46b1e14588
--- /dev/null
+++ b/dev-python/pyro5/pyro5-5.15-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN^}
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Distributed object middleware for Python (RPC)"
+HOMEPAGE="
+	https://pyro5.readthedocs.io/
+	https://github.com/irmen/Pyro5/
+	https://pypi.org/project/Pyro5/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/serpent-1.40[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-fix-test-on-ipv6.patch
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/sphinx-rtd-theme
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# https://github.com/irmen/Pyro5/issues/83 (pypy3 specific)
+		tests/test_server.py::TestServerOnce::testRegisterWeak
+	)
+
+	epytest -m 'not network'
+}