xfce-extra/xfce4-screensaver: Bump to 4.18.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 93 insertions, 0 deletions

diff --git a/xfce-extra/xfce4-screensaver/Manifest b/xfce-extra/xfce4-screensaver/Manifest
index 70b6d370a08b..8e6cf937d66b 100644
--- a/xfce-extra/xfce4-screensaver/Manifest
+++ b/xfce-extra/xfce4-screensaver/Manifest
@@ -1 +1,2 @@
 DIST xfce4-screensaver-4.18.3.tar.bz2 722788 BLAKE2B ee3aafc2250209a20a69fefcd0581bc80fe8f4c5a71d394850efee90c0127ba20bce95e6aa1a411e2b619e2dff70d4d36bda35395c24bb985823141a1f9629dd SHA512 1be2227bf108ccbe48647feb64d532251c3e636fcc0163801f62759828c2549490b0fd13047f68fff3c10ee09033a526311db63629b889453aaf64797097e871
+DIST xfce4-screensaver-4.18.4.tar.bz2 896547 BLAKE2B ba240b37cad4f2c7f7f9c9cfa9bc280e2329f5565c98315920429b3ca0c4e333b528fbf8390761d86253ef2e58f1226097d123a62e4cf5276cceaf21f316421c SHA512 1cc30b8262ee53446671ac3dd28b108aed13c37aa565a34809285f14fb5ef9f883c5317cfb798a4012e034a8997ad05c4a402128e10fd263a58c2770d0feefaa
diff --git a/xfce-extra/xfce4-screensaver/xfce4-screensaver-4.18.4.ebuild b/xfce-extra/xfce4-screensaver/xfce4-screensaver-4.18.4.ebuild
new file mode 100644
index 000000000000..4bef54b39eea
--- /dev/null
+++ b/xfce-extra/xfce4-screensaver/xfce4-screensaver-4.18.4.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Screen saver and locker (port of MATE screensaver)"
+HOMEPAGE="
+	https://docs.xfce.org/apps/screensaver/start
+	https://gitlab.xfce.org/apps/xfce4-screensaver/
+"
+SRC_URI="
+	https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2
+"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="elogind +locking opengl pam systemd"
+
+# Xrandr: optional but automagic
+DEPEND="
+	>=dev-libs/dbus-glib-0.30
+	>=dev-libs/glib-2.50.0:2
+	>=x11-libs/gtk+-3.24.0:3
+	>=x11-libs/libwnck-3.20:3
+	x11-libs/libICE:=
+	x11-libs/libX11:=
+	x11-libs/libXScrnSaver:=
+	x11-libs/libXext:=
+	x11-libs/libXxf86vm:=
+	>=x11-libs/libXrandr-1.3:=
+	>=x11-libs/libxklavier-5.2:=
+	>=xfce-base/garcon-0.5.0:=
+	>=xfce-base/libxfce4ui-4.18.4:=
+	>=xfce-base/libxfce4util-4.12.1:=
+	>=xfce-base/xfconf-4.12.1:=
+	elogind? ( sys-auth/elogind )
+	locking? (
+		pam? ( sys-libs/pam )
+	)
+	opengl? ( virtual/opengl )
+	systemd? ( sys-apps/systemd:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/glib-utils
+	sys-apps/dbus
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		# disable docbook for now
+		ac_cv_path_XMLTO=no
+
+		# xscreensaver dirs autodetection doesn't seem to work
+		--with-xscreensaverdir=/usr/share/xscreensaver/config
+		--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+		--without-console-kit
+
+		$(use_with opengl libgl)
+		$(use_enable locking)
+		$(use_enable pam)
+		$(use_with elogind)
+		$(use_with systemd)
+	)
+
+	if use pam; then
+		myconf+=( --with-pam-auth-type=system )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}