sys-libs/tdb: Bump to version 1.4.2

Package-Manager: Portage-2.3.72, Repoman-2.3.17
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/sys-libs/tdb/tdb-1.4.2.ebuild b/sys-libs/tdb/tdb-1.4.2.ebuild
new file mode 100644
index 000000000000..8e8d3ce12a4b
--- /dev/null
+++ b/sys-libs/tdb/tdb-1.4.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit waf-utils multilib-minimal python-single-r1
+
+DESCRIPTION="A simple database API"
+HOMEPAGE="http://tdb.samba.org/"
+SRC_URI="http://samba.org/ftp/tdb/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="python"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="!elibc_FreeBSD? ( dev-libs/libbsd[${MULTILIB_USEDEP}] )
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="
+	${RDEPEND}
+	${PYTHON_DEPS}
+	app-text/docbook-xml-dtd:4.2"
+
+WAF_BINARY="${S}/buildtools/bin/waf"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	python_fix_shebang .
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local extra_opts=()
+	if ! multilib_is_native_abi || ! use python; then
+		extra_opts+=( --disable-python )
+	fi
+
+	waf-utils_src_configure "${extra_opts[@]}"
+}
+
+multilib_src_compile() {
+	# need to avoid parallel building, this looks like the sanest way with waf-utils/multiprocessing eclasses
+	unset MAKEOPTS
+	waf-utils_src_compile
+}
+
+multilib_src_test() {
+	# the default src_test runs 'make test' and 'make check', letting
+	# the tests fail occasionally (reason: unknown)
+	emake check
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+}