sys-fs/lxcfs: add 5.0.1

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/sys-fs/lxcfs/Manifest b/sys-fs/lxcfs/Manifest
index 9286cf363909..8277a30a42fe 100644
--- a/sys-fs/lxcfs/Manifest
+++ b/sys-fs/lxcfs/Manifest
@@ -1 +1,3 @@
 DIST lxcfs-5.0.0_p20220524.tar.gz 101563 BLAKE2B 2bf282aed5490d160a563ae97fdfbb887366a6ec60ea7f36f5400e4a11330c51ac3096d63c99dd4aa2ebe1a3497102af9df41ebd40e38b3bde6c6dcd4265b336 SHA512 c1183096dd2b74ef859183451b8c909f762e3c56dce0b9384ac163a6b6b3f7a17a63e840742f4cc5ac50b1f25d402583ca6cf31c1617754b35e21c5c991515f4
+DIST lxcfs-5.0.1.tar.gz 103221 BLAKE2B 49cd0be04d358db81046ac78e66e8acaa86ef66e51a869b884cb75e98c0501ee7db1b1e5604ca44f105f04378418e8077738a6d6abf85c48b35dfee2b93131e9 SHA512 edc685914e73b055161b8efe9109aca7bc2b1f1285e06a71b697f97d2e7f4cddf5256519325bf628318b64ae0203f594928d9e772e04988971151c4e46788818
+DIST lxcfs-5.0.1.tar.gz.asc 833 BLAKE2B a280e506f154497af3cc6a61bf458830939c67a6a065da1c0509f44ed07bd58bf80c10b5bfdbb18027ae2f200aaa2e9ca4b76cde070b860c34fb2cca7083e809 SHA512 90b982b61fcc56ac23fcef344014252faba280a8fb7539d28dbe2d36dc433c8de93d2c065d160cb98b42ab4b341d01ff2a379cad12827d8b70885c044e9e9ae8
diff --git a/sys-fs/lxcfs/lxcfs-5.0.1.ebuild b/sys-fs/lxcfs/lxcfs-5.0.1.ebuild
new file mode 100644
index 000000000000..9af4475e9807
--- /dev/null
+++ b/sys-fs/lxcfs/lxcfs-5.0.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake meson python-any-r1 systemd verify-sig
+
+DESCRIPTION="FUSE filesystem for LXC"
+HOMEPAGE="https://linuxcontainers.org/lxcfs/introduction/ https://github.com/lxc/lxcfs/"
+SRC_URI="https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz
+	verify-sig? ( https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz.asc )"
+
+LICENSE="Apache-2.0 LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="doc test"
+
+DEPEND="sys-fs/fuse:3"
+RDEPEND="${DEPEND}"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep '
+		dev-python/jinja[${PYTHON_USEDEP}]
+	')
+	doc? ( sys-apps/help2man )
+	verify-sig? ( sec-keys/openpgp-keys-linuxcontainers )"
+
+# Needs some black magic to work inside container/chroot.
+RESTRICT="test"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/linuxcontainers.asc
+
+python_check_deps() {
+	python_has_version -b "dev-python/jinja[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Fix python shebangs for python-exec[-native-symlinks], #851480
+	local shebangs=($(grep -rl "#!/usr/bin/env python3" || die))
+	python_fix_shebang -q ${shebangs[*]}
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc docs)
+		$(meson_use test tests)
+
+		-Dfuse-version=3
+		-Dinit-script=""
+		-Dwith-init-script=""
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}"/tests || die "failed to change into tests/ directory."
+	./main.sh || die
+}
+
+src_install() {
+	meson_src_install
+
+	newconfd "${FILESDIR}"/lxcfs-4.0.0.confd lxcfs
+	newinitd "${FILESDIR}"/lxcfs-4.0.0.initd lxcfs
+
+	# Provide our own service file (copy of upstream) due to paths being different from upstream,
+	# #728470
+	systemd_newunit "${FILESDIR}"/lxcfs-4.0.0.service lxcfs.service
+}