sys-boot/unetbootin: Version bump.

Package-Manager: portage-2.3.0_rc1

3 files changed, 95 insertions, 3 deletions

diff --git a/sys-boot/unetbootin/Manifest b/sys-boot/unetbootin/Manifest
index a8af19bd9bcf..6165084993dd 100644
--- a/sys-boot/unetbootin/Manifest
+++ b/sys-boot/unetbootin/Manifest
@@ -1,2 +1,3 @@
-DIST 619.tar.gz 22669784 SHA256 84bd5b29a46f61156868acf0d069c2c6b3ec13435dc11cc82f93e8c30523966f SHA512 81a02c0b7866f878139133562db745538f1f22fb90231a228792dccd3c5ff0c1c7cefc435b34cc14302b0d2b20e97342295fb65c7f28c220a637b1d52fa77e3c WHIRLPOOL 66a46933ea16b73f94d95080241103bac985694bc7b28e4213341aa9e6cb03f0fdf85bc19f9491b1ac97cba2ac83edfdba31965b9d138ef46bbf337bf03ded05
+DIST unetbootin-619.tar.gz 22669784 SHA256 84bd5b29a46f61156868acf0d069c2c6b3ec13435dc11cc82f93e8c30523966f SHA512 81a02c0b7866f878139133562db745538f1f22fb90231a228792dccd3c5ff0c1c7cefc435b34cc14302b0d2b20e97342295fb65c7f28c220a637b1d52fa77e3c WHIRLPOOL 66a46933ea16b73f94d95080241103bac985694bc7b28e4213341aa9e6cb03f0fdf85bc19f9491b1ac97cba2ac83edfdba31965b9d138ef46bbf337bf03ded05
+DIST unetbootin-625.tar.gz 22671470 SHA256 1c63265cbbeccfb0c45978e5235a35fcdb6f40fdd6a8b438539c1785703d05a1 SHA512 0dc672097eb857f8516208f8cbe5a0ec3229aa5dbe56108f64c415d2d9d4679a41e3f8a4b7279c511197303a2e020c95293a305de4df2dc63dc4522b3d13259b WHIRLPOOL 2444d5ca7be19d1747de641e92bb4c255c0298faac9d446eadbb3ce0b28ed7a57822c83fdebce2aaeacefa3ca0718250ca967d12e2b4fb0e4135d88f042bc93c
 DIST unetbootin-source-608.tar.gz 752043 SHA256 ce99c5f60b1f66da0ceb41859ce9198d96b3061b949b167fc952d3951b632080 SHA512 d164537c96845eb90ac5aae1fa0c553c9392d778696e4818760cb11f78341e6a3ea6a05f702678583c5d680dc8fb1348cdc2b2dfba9bebfdf793779c23611d16 WHIRLPOOL 56cc31e047c283b4f6ef639283c7e9a3e59332fb4f3b70baa279e973c19adc42a276074087b530a49cad41076cf29990c65323d805e0a7b4fccd37bdf1132649
diff --git a/sys-boot/unetbootin/unetbootin-619.ebuild b/sys-boot/unetbootin/unetbootin-619.ebuild
index 740896e4cc02..e9aa223d6db2 100644
--- a/sys-boot/unetbootin/unetbootin-619.ebuild
+++ b/sys-boot/unetbootin/unetbootin-619.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -8,7 +8,7 @@ inherit eutils qmake-utils
 
 DESCRIPTION="UNetbootin installs Linux/BSD distributions to a partition or USB drive"
 HOMEPAGE="https://github.com/unetbootin/unetbootin"
-SRC_URI="${HOMEPAGE}/archive/619.tar.gz -> ${PV}.tar.gz"
+SRC_URI="${HOMEPAGE}/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 SLOT="0"
 LICENSE="GPL-2"
diff --git a/sys-boot/unetbootin/unetbootin-625.ebuild b/sys-boot/unetbootin/unetbootin-625.ebuild
new file mode 100644
index 000000000000..e9aa223d6db2
--- /dev/null
+++ b/sys-boot/unetbootin/unetbootin-625.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils qmake-utils
+
+DESCRIPTION="UNetbootin installs Linux/BSD distributions to a partition or USB drive"
+HOMEPAGE="https://github.com/unetbootin/unetbootin"
+SRC_URI="${HOMEPAGE}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+UNBI_LINGUAS="
+	am ar ast be bg bn ca cs da de el eo es et eu fa fi fo fr gl he hr hu id it
+	ja lt lv ml ms nan nb nl nn pl pt_BR pt ro ru si sk sl sr sv sw tr uk ur vi
+	zh_CN zh_TW
+"
+
+for lingua in ${UNBI_LINGUAS}; do
+	IUSE="${IUSE} linguas_${lingua}"
+done
+
+S=${WORKDIR}/${P}/src/${PN}
+
+DEPEND="dev-qt/qtgui:4"
+RDEPEND="
+	${DEPEND}
+	app-arch/p7zip
+	sys-boot/syslinux
+	sys-fs/mtools
+"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-581-desktop.patch"
+
+	# QA check in case linguas are added or removed
+	enum() {
+		echo ${#}
+	}
+	[[ $(enum ${UNBI_LINGUAS}) -eq $(( $(enum $(echo ${PN}_*.ts) ) -1 )) ]] \
+		|| die "Numbers of recorded and actual linguas do not match"
+	unset enum
+
+	# Make room between the last line of TRANSLATIONS and the next definition
+	sed -i \
+		-e '/^DEFINES/s|.*|\n&|g' \
+		${PN}.pro || die
+
+	# Remove localisations
+	local lingua
+	for lingua in ${UNBI_LINGUAS}; do
+		if ! use linguas_${lingua}; then
+			sed -i ${PN}.pro -e "/\.*${PN}_${lingua}\.ts.*/d" || die
+			rm ${PN}_${lingua}.ts || die
+		fi
+	done
+}
+
+src_configure() {
+	sed -i -e '/^RESOURCES/d' unetbootin.pro || die
+
+	UNBN_QTPATH="$(qt4_get_bindir)/"
+	"${UNBN_QTPATH}"lrelease ${PN}.pro || die
+
+	eqmake4 ${PN}.pro || die
+}
+
+src_install() {
+	dobin ${PN}
+
+	domenu ${PN}.desktop
+
+	for file in ${PN}*.png; do
+		size="${file/${PN}_}"
+		size="${size/.png}x${size/.png}"
+		insinto /usr/share/icons/hicolor/${size}/apps
+		newins ${file} ${PN}.png
+	done
+
+	local lingua
+	for lingua in ${UNBI_LINGUAS}; do
+		if use linguas_${lingua}; then
+			insinto /usr/share/${PN}
+			doins ${PN}_${lingua}.qm
+		fi
+	done
+}