sci-mathematics/pspp: version bump to 1.4.1

Closes: https://github.com/gentoo/gentoo/pull/18417
Signed-off-by: John Helmert III <jchelmert3@posteo.net>
Signed-off-by: David Seifert <soap@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/sci-mathematics/pspp/Manifest b/sci-mathematics/pspp/Manifest
index b6717e465c4d..c165db85af66 100644
--- a/sci-mathematics/pspp/Manifest
+++ b/sci-mathematics/pspp/Manifest
@@ -1 +1,2 @@
 DIST pspp-1.2.0.tar.gz 7213194 BLAKE2B f468c6e025f996c9f806fb03e94a4497f02b774c509457cc6295bbefe37abc7e2ecf10d2876c8cff9a979d7a4264c7c185e1cec5fd1d5f2f00f1c6eae4da775e SHA512 49eed2b55f10584abba18ff7d2020fd08691bbc1a3c2f332e6d283e32aa84e0abdae6092d17db9c1a539c63d85ecdfcc2dad40c94a06904b8893a1976e5e48d3
+DIST pspp-1.4.1.tar.gz 7848393 BLAKE2B c9232aa3d4905d4be54ae993db6a4b37b3696c748e15c8ba6c46c7e56f9974aefe597f893fdc5431af237ad3923da1ef271db39e4d94725ccf93f0a0df443ef4 SHA512 c664a6c6f4f1826db396ad776d81cadc791e4f661c603a7f164f70f9571a84cfae6fec116356b3f950991245b2b0dc9805e75193a055a242558cda1209e7830f
diff --git a/sci-mathematics/pspp/pspp-1.4.1.ebuild b/sci-mathematics/pspp/pspp-1.4.1.ebuild
new file mode 100644
index 000000000000..5c58d5dba490
--- /dev/null
+++ b/sci-mathematics/pspp/pspp-1.4.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit python-any-r1 xdg
+
+DESCRIPTION="Program for statistical analysis of sampled data"
+HOMEPAGE="https://www.gnu.org/software/pspp/pspp.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cairo doc examples gtk ncurses nls perl postgres test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="test? ( cairo )"
+
+RDEPEND="
+	dev-libs/libxml2:2
+	sci-libs/gsl:0=
+	sys-devel/gettext
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	sys-libs/zlib
+	virtual/libiconv
+	cairo? (
+		x11-libs/cairo[svg]
+		x11-libs/pango
+	)
+	gtk? (
+		x11-libs/gtk+:3
+		x11-libs/gtksourceview:3.0=
+		>=x11-libs/spread-sheet-widget-0.6
+		cairo? ( dev-util/glib-utils )
+	)
+	postgres? ( dev-db/postgresql:=[server] )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( virtual/latex-base )
+	test? ( ${PYTHON_DEPS} )"
+
+pkg_pretend() {
+	ewarn "Starting with pspp-1.4.0 the pspp-mode emacs package is no longer"
+	ewarn "shipped with pspp itself, and should instead be fetched from ELPA:"
+	ewarn "https://elpa.gnu.org/packages/pspp-mode.html"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed -i '/appdata$/s/appdata$/metainfo/' Makefile.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		$(use_enable nls) \
+		$(use_with cairo) \
+		$(use_with gtk gui) \
+		$(use_with perl perl-module) \
+		$(use_with postgres libpq)
+}
+
+src_compile() {
+	default
+	if use doc; then
+		emake html pdf
+		HTML_DOCS=( doc/pspp{,-dev}.html )
+	fi
+}
+
+src_install() {
+	default
+
+	use doc && dodoc doc/pspp{,-dev}.pdf
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	find "${ED}" -name '*.la' -type f -delete || die
+}