net-vpn/networkmanager-sstp: Version bump to 1.2.6

Closes: https://bugs.gentoo.org/608902
Closes: https://bugs.gentoo.org/741108
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 61 insertions, 0 deletions

diff --git a/net-vpn/networkmanager-sstp/Manifest b/net-vpn/networkmanager-sstp/Manifest
index 90ed8233902a..6bf141bbaa3d 100644
--- a/net-vpn/networkmanager-sstp/Manifest
+++ b/net-vpn/networkmanager-sstp/Manifest
@@ -1 +1,2 @@
 DIST NetworkManager-sstp-1.2.0.tar.bz2 440695 BLAKE2B 170221842c25945da09f94364642be94993ac4ef7bbaffebefc463e18eeff78f3a58d95607a6f0be9fb5ecdabee244d64abb02eb56deb213ac089019089821f4 SHA512 31c7f61c2d0326c2ddc681690d4a9e0a25f29b3b5f51c44ea196cd74aab1002a6eb66bd06bddd8218961b18e666d5c28e57cfe0b2694a686ea8eb4195fcd9776
+DIST NetworkManager-sstp-1.2.6.tar.bz2 450813 BLAKE2B 9eefc73a676c825fd56b36085385fc382616059b82f8c14394e315b657162baa608f15046cad584d088774af1432a4e4d3751ecbecc6e779af7080c4bec9034f SHA512 60f5636e73d40ad3e16e5751a22ec12616e8d1fcffe63cba2ae1d04a13edd553c8c72a336ec52d353be6df5431a8a27a74e6e056b1a1a18ed050d5ec226bbe8e
diff --git a/net-vpn/networkmanager-sstp/networkmanager-sstp-1.2.6.ebuild b/net-vpn/networkmanager-sstp/networkmanager-sstp-1.2.6.ebuild
new file mode 100644
index 000000000000..9d5cf1c5a99e
--- /dev/null
+++ b/net-vpn/networkmanager-sstp/networkmanager-sstp-1.2.6.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="NetworkManager-sstp"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Client for the proprietary Microsoft Secure Socket Tunneling Protocol(SSTP)"
+HOMEPAGE="https://sourceforge.net/projects/sstp-client/"
+SRC_URI="mirror://sourceforge/project/sstp-client/network-manager-sstp//${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk"
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	net-misc/sstp-client
+	>=net-misc/networkmanager-1.1.0
+	net-dialup/ppp:=
+	gtk? (
+		>=x11-libs/gtk+-3.4:3
+		>=net-libs/libnma-1.2.0
+		>=app-crypt/libsecret-0.18
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	sys-devel/gettext
+	dev-util/intltool
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# Bug #741108
+	sed -i 's|/appdata|/metainfo|g' Makefile.{in,am} || die
+
+	default
+}
+
+src_configure() {
+	local PPPD_VERSION="$(echo $(best_version net-dialup/ppp) | sed -e 's:net-dialup/ppp-\(.*\):\1:' -e 's:-r.*$::')"
+	econf \
+		--disable-more-warnings \
+		--disable-static \
+		--with-dist-version=Gentoo \
+		--with-pppd-plugin-dir="${EPREFIX}/usr/$(get_libdir)/pppd/${PPPD_VERSION}" \
+		 $(use_with gtk gnome) \
+		 --without-libnm-glib
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+}