net-misc/owncloud-client: 2.4.2 bump

Package-Manager: Portage-2.3.45, Repoman-2.3.10

2 files changed, 92 insertions, 0 deletions

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index 1bdbc8f3748c..f44c24df549b 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1 +1,2 @@
 DIST owncloudclient-2.4.1.tar.xz 15403164 BLAKE2B 0ab1ffbe2179fe04efc7977972d5941a32bc20cd73e310fa72e2a3cf341f7223911fd430f4d34f7e265819acb68d8576e2687a7bfe4ab7140b4c9e9381ea863b SHA512 5b0ceea299078efbc92c1abe22210a93df44bf98094bf4cf8a0c5138f0b69a6719fdc88ef2d5674d49c0ec18ffb12493319eb84616c3e4b8666171cb1a52f0b7
+DIST owncloudclient-2.4.2.tar.xz 15409188 BLAKE2B 89ae891479f29c8637843e14e3aa58d91769393dcfedcfaa415a601962eabd4d1760250fa57166fde215e5c0c5b5799b72dc4f1b52814e59149b778d92d5eb93 SHA512 17f857354b270ecde75cae81557adb78dab830589b32df0b3cf96667010f02501d793609cddf57223d1dd3d9cdb493f1f55bcb04a09d05c467afaddfeb2210b0
diff --git a/net-misc/owncloud-client/owncloud-client-2.4.2.ebuild b/net-misc/owncloud-client/owncloud-client-2.4.2.ebuild
new file mode 100644
index 000000000000..3966ff822847
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.4.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils
+
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="http://owncloud.org/"
+SRC_URI="http://download.owncloud.com/desktop/stable/${P/-}.tar.xz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc dolphin nautilus shibboleth test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	shibboleth? ( dev-qt/qtwebkit:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!net-misc/ocsync
+	!net-misc/nextcloud-client
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)
+"
+
+S=${WORKDIR}/${P/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die "sed failed"
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=$(usex !shibboleth)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}