net-irc/znc-palaver: update EAPI 7 -> 8

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/net-irc/znc-palaver/znc-palaver-1.2.1-r1.ebuild b/net-irc/znc-palaver/znc-palaver-1.2.1-r1.ebuild
new file mode 100644
index 000000000000..73185c6ac198
--- /dev/null
+++ b/net-irc/znc-palaver/znc-palaver-1.2.1-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit python-single-r1 toolchain-funcs
+
+DESCRIPTION="A ZNC module which provides push notifications to Palaver"
+HOMEPAGE="https://github.com/cocodelabs/znc-palaver"
+SRC_URI="https://github.com/cocodelabs/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	net-irc/znc:=[ssl]"
+
+BDEPEND="
+	${RDEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/semantic_version[${PYTHON_USEDEP}]
+	')
+"
+
+DOCS=( "CHANGELOG.md" "README.md" )
+
+PATCHES=(
+	"${FILESDIR}/${P}-python310.patch"
+	"${FILESDIR}/${P}-xunit2.patch"
+)
+
+src_compile() {
+	tc-export CXX
+
+	# Building znc modules by 'znc-buildmod'
+	# does not support multiple threads.
+	emake -j1
+}
+
+src_test() {
+	default
+
+	emake test-integration
+}
+
+src_install() {
+	insinto /usr/$(get_libdir)/znc
+	doins palaver.so
+
+	einstalldocs
+}