media-sound/cava: add 0.10.0

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/media-sound/cava/Manifest b/media-sound/cava/Manifest
index 74101eb03ce0..04db6a2f95dd 100644
--- a/media-sound/cava/Manifest
+++ b/media-sound/cava/Manifest
@@ -1 +1,2 @@
+DIST cava-0.10.0.tar.gz 124085 BLAKE2B 1d1d16f2e32823749465ee76d42bdaebf201dd5d8c7c44020793e247448f6786d631fed75841622dfaedc1d6dd0bee54dfaf10e9f637d6ae5aab3e1a76138421 SHA512 8b54ed59ce7965209f0e03be3409f59b0e59e6a684afca3eb2e3c82c369d35224a0a1a09cbcbca09b36fce416a13efafdff7362fe0b4e2f6b494a023de76793e
 DIST cava-0.9.1.tar.gz 119287 BLAKE2B e6342ff8867747a2c15197c965b713e8ea1c5bd579725538e0e1745797280460ea6a7d6c5cca2776934eef24378d9661bcef5cfd5280a93de16b41201558c49d SHA512 21af220b53a2f45c8c43dfd2ba47c1c96a8fcccdbd11ca1ac59eea7a4f32c0e27c7d2056281d0293fd17d4d635b1c568c953567d6f0301c800b4a387332d2a7a
diff --git a/media-sound/cava/cava-0.10.0.ebuild b/media-sound/cava/cava-0.10.0.ebuild
new file mode 100644
index 000000000000..11b7f54f0efb
--- /dev/null
+++ b/media-sound/cava/cava-0.10.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Console-based Audio Visualizer for Alsa"
+HOMEPAGE="https://github.com/karlstav/cava/"
+SRC_URI="
+	https://github.com/karlstav/cava/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="MIT Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa +ncurses pipewire portaudio pulseaudio sdl sndio"
+
+RDEPEND="
+	dev-libs/iniparser:4
+	sci-libs/fftw:3.0=
+	alsa? ( media-libs/alsa-lib )
+	ncurses? ( sys-libs/ncurses:= )
+	pipewire? ( media-video/pipewire:= )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sdl? (
+		media-libs/libglvnd
+		media-libs/libsdl2[opengl,video]
+	)
+	sndio? ( media-sound/sndio:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	sdl? ( sys-devel/autoconf-archive )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.8.0-gentoo-iniparser4.patch
+)
+
+src_prepare() {
+	default
+
+	echo ${PV} > version || die
+	eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		$(use_enable alsa input-alsa)
+		$(use_enable pipewire input-pipewire)
+		$(use_enable portaudio input-portaudio)
+		$(use_enable pulseaudio input-pulse)
+		$(use_enable sndio input-sndio)
+
+		$(use_enable ncurses output-ncurses)
+		$(use_enable sdl output-sdl)
+		# note: not behind USE=opengl and sdl2[opengl?] given have not gotten
+		# normal output-sdl to work without USE=opengl on sdl either way
+		$(use_enable sdl output-sdl_glsl)
+
+		GENTOO_SYSROOT="${ESYSROOT}" # see iniparser4.patch
+	)
+
+	# autoconf-archive (currently) does not support -lOpenGL for libglvnd[-X]
+	use sdl && econfargs+=( GL_LIBS="$($(tc-getPKG_CONFIG) --libs opengl || die)" )
+
+	econf "${econfargs[@]}"
+}
+
+pkg_postinst() {
+	if [[ ! ${REPLACING_VERSIONS##* } ]]; then
+		elog "A default ~/.config/cava/config will be created after initial"
+		elog "use of ${PN}, see it and ${EROOT}/usr/share/doc/${PF}/README*"
+		elog "for configuring audio input and more."
+	elif ver_test ${REPLACING_VERSIONS##* } -lt 0.9; then
+		elog "If used, the noise_reduction config option in ~/.config/cava/config needs"
+		elog "to be updated from taking a float to integer (e.g. replace 0.77 with 77)."
+	fi
+}