media-sound/qsynth: bump to 0.9.5, cleanup

dropped unused eclass, updated live

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

4 files changed, 77 insertions, 5 deletions

diff --git a/media-sound/qsynth/Manifest b/media-sound/qsynth/Manifest
index 6f5ae1ffe544..f48c0a084fce 100644
--- a/media-sound/qsynth/Manifest
+++ b/media-sound/qsynth/Manifest
@@ -1 +1,2 @@
 DIST qsynth-0.9.4.tar.gz 395550 BLAKE2B e25195755c52c63912b03a416878d248712b78ba0014414bc8b1d31cbd5bb75562640de4a0255d2727a40274a6ff3a84b201d39c93674140ff31ccc581bfd254 SHA512 764a90fd86451cd3a12c71f061f4a603cdce54ae80e6543d05fa66a97ea0b7c50bac0350f01f597ec93ed445a5433a9dea6d9c5a43ce385c231aaea8e13675d4
+DIST qsynth-0.9.5.tar.gz 331213 BLAKE2B 3973c2ea0599b8bf9f12c3ce1bb7eff00b5d20b4f051ebcb578f556dbfce714cbe0bf77038b553289f27cfedc521bd7e179af652c721375e6bedc4d22ce061d5 SHA512 157e49e8ebfcf550754379c4f2bae221354cffbfe47dcaea747749c00520339f59de5fe7f17e105674ecc6099a98af5f2326d2d258fe359c0c7522366f4267d4
diff --git a/media-sound/qsynth/qsynth-0.9.4.ebuild b/media-sound/qsynth/qsynth-0.9.4.ebuild
index a9c46977ac25..42c724b0c2e2 100644
--- a/media-sound/qsynth/qsynth-0.9.4.ebuild
+++ b/media-sound/qsynth/qsynth-0.9.4.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-inherit cmake desktop qmake-utils xdg
+inherit cmake desktop xdg
 
 DESCRIPTION="Qt application to control FluidSynth"
 HOMEPAGE="https://qsynth.sourceforge.io/"
diff --git a/media-sound/qsynth/qsynth-0.9.5.ebuild b/media-sound/qsynth/qsynth-0.9.5.ebuild
new file mode 100644
index 000000000000..802d146a7511
--- /dev/null
+++ b/media-sound/qsynth/qsynth-0.9.5.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake desktop xdg
+
+DESCRIPTION="Qt application to control FluidSynth"
+HOMEPAGE="https://qsynth.sourceforge.io/"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.code.sf.net/p/qsynth/code"
+	inherit git-r3
+else
+	SRC_URI="mirror://sourceforge/qsynth/${P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+alsa debug jack pulseaudio"
+
+REQUIRED_USE="|| ( alsa jack pulseaudio )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	media-sound/fluidsynth:=[jack?,alsa?,pulseaudio?]
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-0.9.1-cmake-no-git-version.patch" )
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -e "/^find_package.*QT/s/Qt6 //" -i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFIG_DEBUG=$(usex debug 1 0)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# The desktop file is invalid, and we also change the command
+	# depending on useflags
+	rm "${D}/usr/share/applications/org.rncbc.qsynth.desktop" || die
+
+	local cmd
+	if use jack; then
+		cmd="qsynth"
+	elif use pulseaudio; then
+		cmd="qsynth -a pulseaudio"
+	elif use alsa; then
+		cmd="qsynth -a alsa"
+	else
+		cmd="qsynth -a oss"
+	fi
+
+	make_desktop_entry "${cmd}" Qsynth qsynth
+}
diff --git a/media-sound/qsynth/qsynth-9999.ebuild b/media-sound/qsynth/qsynth-9999.ebuild
index f2e790dc5a2b..764b1b7b1cea 100644
--- a/media-sound/qsynth/qsynth-9999.ebuild
+++ b/media-sound/qsynth/qsynth-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-inherit cmake desktop qmake-utils xdg
+inherit cmake desktop xdg
 
 DESCRIPTION="Qt application to control FluidSynth"
 HOMEPAGE="https://qsynth.sourceforge.io/"
@@ -52,7 +52,7 @@ src_install() {
 
 	# The desktop file is invalid, and we also change the command
 	# depending on useflags
-	rm "${D}/usr/share/applications/qsynth.desktop" || die
+	rm "${D}/usr/share/applications/org.rncbc.qsynth.desktop" || die
 
 	local cmd
 	if use jack; then