media-fonts/noto-emoji: drop 20211101

Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 0 insertions, 113 deletions

diff --git a/media-fonts/noto-emoji/Manifest b/media-fonts/noto-emoji/Manifest
index 2d447e0d20f0..d8cbfd497ba1 100644
--- a/media-fonts/noto-emoji/Manifest
+++ b/media-fonts/noto-emoji/Manifest
@@ -1,2 +1 @@
-DIST noto-emoji-20211101.tar.gz 170403395 BLAKE2B d37ef3b11c339d2d2f2a8c1b6370551c14fbe3d902a51a956b6cb89592001a751656a2050f6501619f770d53fefbdf6b1223725967206c9f13072928ebacbfe0 SHA512 b80d3ca838e0cc66b6b6af9b368164da3f40bd22cfbb1d923a172bd51e87f1db9b7722494f220e4e912160664bb1c5318bbd9253981c1262ce563482d6cad7a4
 DIST noto-emoji-20220912.tar.gz 178768907 BLAKE2B b998a74903e0a559e6c2d87f6d05649054728d5359659882c89b99fc41ec80f9dbafba6f418500059acef7bb85b9d60b189abea286c9c4cb5491f501095ca425 SHA512 4e9b01be1ac7853d840379f84350f2709212401ccebb221308eb83982a8673af9a8ef166952aba4d6f8d9939efc4989f38a7db69e022eb055f265ccba78884a6
diff --git a/media-fonts/noto-emoji/noto-emoji-20211101.ebuild b/media-fonts/noto-emoji/noto-emoji-20211101.ebuild
deleted file mode 100644
index 8d4899112c42..000000000000
--- a/media-fonts/noto-emoji/noto-emoji-20211101.ebuild
+++ /dev/null
@@ -1,112 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit font python-any-r1
-
-DESCRIPTION="Google Noto Emoji fonts"
-HOMEPAGE="https://www.google.com/get/noto/ https://github.com/googlefonts/noto-emoji"
-
-COMMIT="9a5261d871451f9b5183c93483cbd68ed916b1e9"
-SRC_URI="https://github.com/googlefonts/noto-emoji/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="Apache-2.0 OFL-1.1"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv x86"
-IUSE="buildfont"
-
-BDEPEND="
-	buildfont? (
-		${PYTHON_DEPS}
-		app-arch/zopfli
-		$(python_gen_any_dep '
-			>=dev-python/fonttools-4.7.0[${PYTHON_USEDEP}]
-			>=dev-python/nototools-0.2.13[${PYTHON_USEDEP}]
-		')
-		media-gfx/pngquant
-		x11-libs/cairo
-		|| ( media-gfx/imagemagick[png] media-gfx/graphicsmagick[png] )
-	)
-"
-
-RESTRICT="binchecks strip"
-
-S="${WORKDIR}/${PN}-${COMMIT}"
-
-python_check_deps() {
-	python_has_version ">=dev-python/fonttools-4.7.0[${PYTHON_USEDEP}]" \
-		">=dev-python/nototools-0.2.13[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	font_pkg_setup
-	use buildfont && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# Drop font for Windows 10
-	rm fonts/NotoColorEmoji_WindowsCompatible.ttf || die
-
-	if use buildfont; then
-		# From Fedora
-		eapply "${FILESDIR}/${PN}-build-all-flags.patch"
-
-		# https://github.com/googlei18n/noto-emoji/issues/240
-		eapply "${FILESDIR}/${PN}-20180823-build-path.patch"
-
-		# Be more verbose, bug #717654
-		eapply "${FILESDIR}"/${PN}-pngquant-verbose.patch
-		sed -i -e 's:@$(ZOPFLIPNG) -y "$<" "$@" 1> /dev/null 2>&1:@$(ZOPFLIPNG) -y "$<" "$@":g' Makefile || die
-
-		# Based on Fedora patch to allow graphicsmagick usage
-		if has_version -b media-gfx/graphicsmagick; then
-			eapply "${FILESDIR}/${PN}-20190328-use-gm.patch"
-		fi
-	fi
-}
-
-src_compile() {
-	if ! use buildfont; then
-		einfo "Installing pre-built fonts provided by upstream."
-		einfo "They could be not fully updated or miss some items."
-		einfo "To build fonts based on latest images enable 'buildfont'"
-		einfo "USE (that will require more time and resources too)."
-	else
-		python_setup
-		einfo "Building fonts..."
-
-		# From Debian:
-		# The build requires a VIRTUAL_ENV variable and sequence check isn't working
-		VIRTUAL_ENV=true \
-		BYPASS_SEQUENCE_CHECK=true \
-		default
-	fi
-}
-
-src_install() {
-	if ! use buildfont; then
-		FONT_S="${S}/fonts"
-	else
-		mv -i fonts/NotoEmoji-Regular.ttf "${S}" || die
-		# Built font and Regular font
-		FONT_S="${S}"
-
-		# Don't lose fancy emoji icons
-		for i in 32 72 128 512; do
-			insinto "/usr/share/icons/${PN}/${i}/emotes/"
-			doins png/"${i}"/*.png
-		done
-
-		insinto /usr/share/icons/"${PN}"/scalable/emotes/
-		doins svg/*.svg
-	fi
-
-	FONT_SUFFIX="ttf"
-	font_src_install
-
-	dodoc README.md
-}