mate-base/mate-session-manager: bump to 1.22.1

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Göktürk Yüksek <gokturk@gentoo.org>

2 files changed, 93 insertions, 0 deletions

diff --git a/mate-base/mate-session-manager/Manifest b/mate-base/mate-session-manager/Manifest
index e648f5d89752..b69761af5564 100644
--- a/mate-base/mate-session-manager/Manifest
+++ b/mate-base/mate-session-manager/Manifest
@@ -1 +1,2 @@
 DIST mate-session-manager-1.22.0.tar.xz 603016 BLAKE2B 5d7064756b7d7d2ca4fdebf18319dc8a8d8eca6ed31c5e8e37e503c7099a0d541186028d6b4e174bff1ce9ca727a374e9597498b2ca6d5494dc74f21fec0baeb SHA512 7e5e21e37c7ac55ca7d71302edef9aabeccf39233aec9edfe93a2fdcd4150d039e8121adecebb3d0a4a707eccef0c7afa1b54c5b52b57853242964c7506eeb9a
+DIST mate-session-manager-1.22.1.tar.xz 580992 BLAKE2B 313f353597b072e0bc118f5e52258c73e4f5c9c51f0e27ed5c7763591b27df77a37439487b05142de99bbae19e595f01501189449331ca5dcf59ba0c5143a95c SHA512 1c47134813d24abef7b2f5df098120a2cd138f822ea3d687a1a2566224bbde21482bf40ac47ba08a39ed0899ff35eeac3c3690c83c006774c47f22189688990b
diff --git a/mate-base/mate-session-manager/mate-session-manager-1.22.1.ebuild b/mate-base/mate-session-manager/mate-session-manager-1.22.1.ebuild
new file mode 100644
index 000000000000..e42570ea404c
--- /dev/null
+++ b/mate-base/mate-session-manager/mate-session-manager-1.22.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="MATE session manager"
+HOMEPAGE="https://mate-desktop.org/"
+
+LICENSE="GPL-2 LGPL-2 FDL-1.1"
+SLOT="0"
+IUSE="debug elibc_FreeBSD elogind gnome-keyring ipv6 systemd +xtrans"
+
+REQUIRED_USE="?? ( elogind systemd )"
+
+# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
+# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
+# xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).
+
+COMMON_DEPEND="
+	>=dev-libs/dbus-glib-0.76
+	>=dev-libs/glib-2.50:2
+	dev-libs/libxslt
+	sys-apps/dbus
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango
+	virtual/libintl
+	elibc_FreeBSD? ( || ( dev-libs/libexecinfo >=sys-freebsd/freebsd-lib-10.0 ) )
+	systemd? ( sys-apps/systemd )
+	!systemd? (
+		elogind? ( sys-auth/elogind )
+		!elogind? ( >=sys-auth/consolekit-0.9.2 )
+	)
+	xtrans? ( x11-libs/xtrans )"
+
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xdpyinfo
+	x11-misc/xdg-user-dirs
+	x11-misc/xdg-user-dirs-gtk
+	gnome-keyring? ( gnome-base/gnome-keyring )
+	!<gnome-base/gdm-2.20.4"
+
+DEPEND="${COMMON_DEPEND}
+	>=dev-lang/perl-5
+	dev-util/glib-utils
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.10.40
+	virtual/pkgconfig"
+
+MATE_FORCE_AUTORECONF=true
+
+src_configure() {
+	mate_src_configure \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_with elogind) \
+		$(use_with systemd) \
+		$(use_with xtrans)  \
+		$(use_enable debug) \
+		$(use_enable ipv6)
+}
+
+src_install() {
+	mate_src_install
+
+	dodir /etc/X11/Sessions/
+	exeinto /etc/X11/Sessions/
+	doexe "${FILESDIR}"/MATE
+
+	dodir /usr/share/mate/applications/
+	insinto /usr/share/mate/applications/
+	doins "${FILESDIR}"/defaults.list
+
+	dodir /etc/X11/xinit/xinitrc.d/
+	exeinto /etc/X11/xinit/xinitrc.d/
+	doexe "${FILESDIR}"/15-xdg-data-mate
+
+	# This should be done in MATE too, see Gentoo bug #270852
+	doexe "${FILESDIR}"/10-user-dirs-update-mate
+}