kde-misc/kdeconnect: Drop 20.08.1 (r0)

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 0 insertions, 85 deletions

diff --git a/kde-misc/kdeconnect/kdeconnect-20.08.1.ebuild b/kde-misc/kdeconnect/kdeconnect-20.08.1.ebuild
deleted file mode 100644
index be85ee3bf6af..000000000000
--- a/kde-misc/kdeconnect/kdeconnect-20.08.1.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-ECM_HANDBOOK="optional"
-ECM_TEST="true"
-KDE_ORG_NAME="${PN}-kde"
-KDE_RELEASE_SERVICE="true"
-KDE_SELINUX_MODULE="${PN}"
-KFMIN=5.72.0
-QTMIN=5.14.2
-inherit ecm kde.org
-
-DESCRIPTION="Adds communication between KDE Plasma and your smartphone"
-HOMEPAGE="https://kdeconnect.kde.org/
-https://kde.org/applications/internet/org.kde.kdeconnect.kcm"
-
-LICENSE="GPL-2+"
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="bluetooth pulseaudio wayland X"
-
-DEPEND="
-	>=app-crypt/qca-2.3.0:2[ssl]
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtdeclarative-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtmultimedia-${QTMIN}:5
-	>=dev-qt/qtnetwork-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=kde-frameworks/kcmutils-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kirigami-${KFMIN}:5
-	>=kde-frameworks/knotifications-${KFMIN}:5
-	>=kde-frameworks/kpeople-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/plasma-${KFMIN}:5
-	>=kde-frameworks/solid-${KFMIN}:5
-	bluetooth? ( >=dev-qt/qtbluetooth-${QTMIN}:5 )
-	X? (
-		>=dev-qt/qtx11extras-${QTMIN}:5
-		x11-libs/libfakekey
-		x11-libs/libX11
-		x11-libs/libXtst
-	)
-	pulseaudio? ( media-libs/pulseaudio-qt )
-	wayland? ( >=kde-frameworks/kwayland-${KFMIN}:5 )
-"
-RDEPEND="${DEPEND}
-	dev-libs/kpeoplevcard
-	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
-	>=dev-qt/qtquickcontrols2-${QTMIN}:5
-	>=kde-frameworks/kdeclarative-${KFMIN}:5
-	net-fs/sshfs
-"
-
-RESTRICT+=" test"
-
-src_configure() {
-	local mycmakeargs=(
-		-DBLUETOOTH_ENABLED=$(usex bluetooth)
-		$(cmake_use_find_package pulseaudio KF5PulseAudioQt)
-		$(cmake_use_find_package wayland KF5Wayland)
-		$(cmake_use_find_package X LibFakeKey)
-	)
-
-	ecm_src_configure
-}
-
-pkg_postinst(){
-	ecm_pkg_postinst
-
-	elog "The Android .apk file is available via"
-	elog "https://play.google.com/store/apps/details?id=org.kde.kdeconnect_tp"
-	elog "or via"
-	elog "https://f-droid.org/repository/browse/?fdid=org.kde.kdeconnect_tp"
-}