kde-apps/akonadi: 23.08.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 113 insertions, 0 deletions

diff --git a/kde-apps/akonadi/Manifest b/kde-apps/akonadi/Manifest
index f0c128a59806..d8c588da6323 100644
--- a/kde-apps/akonadi/Manifest
+++ b/kde-apps/akonadi/Manifest
@@ -1,2 +1,3 @@
 DIST akonadi-23.04.3.tar.xz 1668012 BLAKE2B a09f26c3b90885babe32af63c1d48cc476862129b6a700884f4a5ecbd73cfc6d60fa6f503e87b7ced746580ccfb7bd2d08c2d3b2454ce7ab7e81664f0d9f1806 SHA512 fc9729451ac8e39c4455748a5fd9fd1efd82573c21731d60dbad59bc02e75e3653bae6469b2d04b68c360fd5f23bc49914d07d849a71a71e1349bd76ae6c8dbc
 DIST akonadi-23.08.1.tar.xz 1662188 BLAKE2B 4bba020310077b95a182d3d8b59988fb8ddae6d35dbef1e666e78f08b5ed39dd5af4436451dd4fb4dbaeec373e9b3469eba2ed808d37227bb473bf020390d2ca SHA512 12248423e3e0f3987e9b5a10a6867f61e28babcbf60bd24b415caf947f853f923198b44de86e203acae8cae7ca44ffb9079d5d37b5a1e3a88e799c612bde2058
+DIST akonadi-23.08.2.tar.xz 1662364 BLAKE2B 78c4b3d48178945e8f58645a8a15705c00c93126c862e883f2765e02db970575d0cf86b8debe8b9c2717d17766ef51f42edbe533f7f92f2195c7cdc1ab0cb0aa SHA512 6a2d02009ad118689f52ed0a7abeac3ec9b640732ee0285ddb88ec106a899f69acdb73e1b9ef06bb2a420dd5cfc2201b78ba5364b6f30074e8ebf4445a4f3285
diff --git a/kde-apps/akonadi/akonadi-23.08.2.ebuild b/kde-apps/akonadi/akonadi-23.08.2.ebuild
new file mode 100644
index 000000000000..b44808223f93
--- /dev/null
+++ b/kde-apps/akonadi/akonadi-23.08.2.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_DESIGNERPLUGIN="true"
+ECM_QTHELP="true"
+ECM_TEST="forceoptional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+VIRTUALDBUS_TEST="true"
+inherit ecm gear.kde.org readme.gentoo-r1
+
+DESCRIPTION="Storage service for PIM data and libraries for PIM apps"
+HOMEPAGE="https://community.kde.org/KDE_PIM/akonadi"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+kaccounts +mysql postgres sqlite tools xml"
+
+REQUIRED_USE="|| ( mysql postgres sqlite ) test? ( tools )"
+
+# some akonadi tests time out, that probably needs more work as it's ~700 tests
+RESTRICT="test"
+
+COMMON_DEPEND="
+	app-arch/xz-utils
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[mysql?,postgres?,sqlite?]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	kaccounts? (
+		>=kde-apps/kaccounts-integration-20.08.3:5
+		>=net-libs/accounts-qt-1.16
+	)
+	xml? ( dev-libs/libxml2 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	test? ( sys-apps/dbus )
+"
+RDEPEND="${COMMON_DEPEND}
+	mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-21.03.80-mysql56-crash.patch" )
+
+pkg_setup() {
+	# Set default storage backend in order: MySQL, PostgreSQL, SQLite
+	# reverse driver check to keep the order
+	use sqlite && DRIVER="QSQLITE"
+	use postgres && DRIVER="QPSQL"
+	use mysql && DRIVER="QMYSQL"
+
+	if use mysql && has_version "${CATEGORY}/${PN}[mysql]" && has_version "dev-db/mariadb"; then
+		ewarn
+		ewarn "Attention: Make sure to read README.gentoo after install."
+		ewarn
+	fi
+
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kaccounts AccountsQt5)
+		$(cmake_use_find_package kaccounts KAccounts)
+		-DBUILD_TOOLS=$(usex tools)
+		$(cmake_use_find_package xml LibXml2)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	# Who knows, maybe it accidentally fixes our permission issues
+	cat <<-EOF > "${T}"/akonadiserverrc
+[%General]
+Driver=${DRIVER}
+EOF
+	insinto /usr/share/config/akonadi
+	doins "${T}"/akonadiserverrc
+
+	ecm_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	elog "You can select the storage backend in ~/.config/akonadi/akonadiserverrc."
+	elog "Available drivers are:"
+	use mysql && elog "  QMYSQL"
+	use postgres && elog "  QPSQL"
+	use sqlite && elog "  QSQLITE"
+	elog "${DRIVER} has been set as your default akonadi storage backend."
+	use mysql && elog
+	use mysql && FORCE_PRINT_ELOG=1 readme.gentoo_print_elog
+}