proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 71 insertions, 0 deletions

diff --git a/games-sports/vdrift/vdrift-20120722.ebuild b/games-sports/vdrift/vdrift-20120722.ebuild
new file mode 100644
index 000000000000..14dddff12b9c
--- /dev/null
+++ b/games-sports/vdrift/vdrift-20120722.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils scons-utils games
+
+MY_P=${PN}-${PV:0:4}-${PV:4:2}-${PV:6:2}
+DESCRIPTION="A driving simulation made with drift racing in mind"
+HOMEPAGE="http://vdrift.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2
+	mirror://sourceforge/${PN}/${MY_P}c_patch.diff"
+
+LICENSE="GPL-3 ZLIB LGPL-2.1+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE=""
+
+RDEPEND="app-arch/libarchive
+	media-libs/glew
+	media-libs/libsdl[opengl,video]
+	media-libs/sdl-gfx
+	media-libs/sdl-image[png]
+	media-libs/libvorbis
+	net-misc/curl
+	sci-physics/bullet[-double-precision]
+	virtual/opengl
+	virtual/glu"
+DEPEND="${RDEPEND}
+	dev-cpp/asio
+	dev-libs/boost
+	virtual/pkgconfig"
+
+S=${WORKDIR}/VDrift
+
+src_unpack() {
+	unpack ${MY_P}.tar.bz2
+}
+
+src_prepare() {
+	epatch \
+		"${DISTDIR}"/${MY_P}c_patch.diff \
+		"${FILESDIR}"/${P}-build.patch \
+		"${FILESDIR}"/${P}-bullet.patch
+}
+
+src_compile() {
+	escons \
+		force_feedback=1 \
+		destdir="${D}" \
+		bindir="${GAMES_BINDIR}" \
+		datadir="${GAMES_DATADIR}"/${PN} \
+		prefix= \
+		use_binreloc=0 \
+		release=1 \
+		os_cc=1 \
+		os_cxx=1 \
+		os_cxxflags=1 \
+		|| die
+}
+
+src_install() {
+	dogamesbin build/vdrift
+	insinto "${GAMES_DATADIR}/${PN}"
+	doins -r data/*
+	newicon data/textures/icons/vdrift-64x64.png ${PN}.png
+	make_desktop_entry ${PN} VDrift
+	find "${D}" -name "SCon*" -exec rm \{\} +
+	keepdir "${GAMES_DATADIR}"/${PN}/{music,settings/replays,settings/screenshots}
+	prepgamesdirs
+}