games-server/etqw-ded: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

1 files changed, 44 insertions, 0 deletions

diff --git a/games-server/etqw-ded/etqw-ded-1.5-r1.ebuild b/games-server/etqw-ded/etqw-ded-1.5-r1.ebuild
new file mode 100644
index 000000000000..9674155798b1
--- /dev/null
+++ b/games-server/etqw-ded/etqw-ded-1.5-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Enemy Territory: Quake Wars dedicated server"
+HOMEPAGE="http://www.splashdamage.com/content/et-quake-wars-standalone-server-linux"
+SRC_URI="ETQW-server-${PV}-full.x86.run"
+
+LICENSE="ETQW"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE=""
+RESTRICT="fetch strip"
+
+DEPEND="app-arch/unzip"
+RDEPEND="sys-libs/glibc"
+
+S=${WORKDIR}/data
+dir=/opt/${PN}
+
+QA_PREBUILT="${dir:1}/pb/*.so
+	${dir:1}/*.x86
+	${dir:1}/*.so*"
+
+pkg_nofetch() {
+	einfo "Please download ${A} from ${HOMEPAGE} and copy it to ${DISTDIR}"
+}
+
+src_unpack() {
+	tail -c +194885 "${DISTDIR}"/${A} > ${A}.zip || die
+	unpack ./${A}.zip
+	rm -f ${A}.zip || die
+}
+
+src_install() {
+	insinto "${dir}"
+	doins -r base pb *.txt
+	exeinto "${dir}"
+	doexe etqwded.x86 *.so*
+	make_wrapper ${PN} ./etqwded.x86 "${dir}" "${dir}"
+}