dev-python/translate-toolkit: Bump to 3.3.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 93 insertions, 0 deletions

diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index ad6ee44d0e46..7faa912d52c8 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1,2 +1,3 @@
 DIST translate-toolkit-3.3.1.tar.gz 5969914 BLAKE2B 2ede440a341be0bd0206400d01bab881e6070820f362c53f47b5f88e192bcb7a18d2bf667a678378110046f70a035d42b67a77e2dc70829da323d69f675d21cc SHA512 1578fb8f96fa83ad97051a20f02d6570f96f2346d99fc86172718c995468c318f318f27f2ef259bd5dc10521bda4ac7da17385f72b726d7ea3c0fe65af8f313e
 DIST translate-toolkit-3.3.2.tar.gz 6123347 BLAKE2B 9bf5f2c84d15043d25744b3bb63526177748c7c38425bd73ad34dcf3b4051c11a3ce28ccaf5c907b6ced27d1fe9ecb06cfde46481a609df64adfedec83b91680 SHA512 53baf7c1203c27335201fbf339e2747d7b22696c219e6911c191b3c89cf6d1c0d84624ffa8c4c687e45fad229d3cb09f52d15d1d80dd914ccc8e2fff34a601be
+DIST translate-toolkit-3.3.3.tar.gz 5903525 BLAKE2B a21c5d89c808615ff2f3f718e732ce5d5591a9d8a997950ae1066655cc3e4382065f75e7a86f8e37bdd0e146283f9bd941ff20479cb1af635f393e0e7f8fc196 SHA512 41964dc26dfbb983b1c2e4cbb0e9d8eb2a035369a94ef872f7703080b5ca0280a9364916a1e1256cd358b263bc72198e767462cc9065b54556fc481d1b85a836
diff --git a/dev-python/translate-toolkit/translate-toolkit-3.3.3.ebuild b/dev-python/translate-toolkit/translate-toolkit-3.3.3.ebuild
new file mode 100644
index 000000000000..fe65fd0c9450
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-3.3.3.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="https://github.com/translate/translate/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND=">=dev-python/six-1.11.0[${PYTHON_USEDEP}]"
+RDEPEND="${BDEPEND}
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+BDEPEND+="
+	test? ( dev-python/phply[${PYTHON_USEDEP}] )"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-bootstrap-theme
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/translate-toolkit-3.3.0-no-install-docs.patch
+)
+
+python_test() {
+	local deselect=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		--deselect 'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		--deselect 'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+	)
+
+	if ! use ini; then
+		deselect+=(
+			--ignore translate/convert/test_ini2po.py
+			--ignore translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		deselect+=(
+			--ignore translate/storage/test_subtitles.py
+		)
+	fi
+
+	# translate/storage/test_mo.py needs 'pocompile'
+	distutils_install_for_testing --via-root
+
+	pytest -vv "${deselect[@]}" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}