dev-python/qscintilla-python: add 2.13.1

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Davide Pesavento <pesa@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-python/qscintilla-python/Manifest b/dev-python/qscintilla-python/Manifest
index 31ba2a34aeaf..03c601dda004 100644
--- a/dev-python/qscintilla-python/Manifest
+++ b/dev-python/qscintilla-python/Manifest
@@ -1,2 +1,3 @@
 DIST QScintilla-2.11.6.tar.gz 3027764 BLAKE2B 1eb5d9ba44040cbff30e8b0028e164cf2aa86c565a5368890500614b9395dbe861c5cd268cf6a4ec06e2c7d77860b2ad6064bc3d07fd63a6ede2b060f44a7117 SHA512 8055d72a40f9f5a7d45c6592055c1b8eb5e5c50ce9e51673babd5e567c769d60c64d244ba5a7def5731a3120099e9528d01ed94327a06bb56ae2fa2e5e37b198
 DIST QScintilla_src-2.13.0.tar.gz 3059601 BLAKE2B 8de5440c3019cb3f67ea25db2935dc8d8cd711298a8a49ce3f632937c538da5b8b337851c3f68c59eb3cb8df8396eebd8ac4f0b4d6d715c2519598eeda9b6586 SHA512 c72676e2d8463dde6e7c620e15a526eae056cfbf00bb5d013c315ebbf20340fcc79188c6e60c336679f7d18287066a26bdc96be2f1ef8a98b3adcada3ee09fd1
+DIST QScintilla_src-2.13.1.tar.gz 3059819 BLAKE2B 147d61cea2d557da6d922599f826a62c4b216f3252226892076ff785a080c9de1fef199297156fce55a00006567240af45e2833e085e423ad47e29c4f9b2241e SHA512 edf7f358e188235d8a39a7d4a8332ca478460a65a8829d9cafcab8f22b84abcd8d624de2076d81a66a56d5a5c53edc6ecc223459bbbb8ac876c5befd8873f700
diff --git a/dev-python/qscintilla-python/qscintilla-python-2.13.1.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.13.1.ebuild
new file mode 100644
index 000000000000..3b9a839cd1c5
--- /dev/null
+++ b/dev-python/qscintilla-python/qscintilla-python-2.13.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit python-r1 qmake-utils
+
+DESCRIPTION="Python bindings for QScintilla"
+HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/ https://pypi.org/project/QScintilla/"
+
+MY_PN=QScintilla
+MY_P=${MY_PN}_src-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
+fi
+S=${WORKDIR}/${MY_P}/Python
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-python/PyQt5-5.15.5[gui,printsupport,widgets,${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	~x11-libs/qscintilla-${PV}:=
+"
+RDEPEND="${DEPEND}
+	>=dev-python/PyQt5-sip-12.9:=[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/PyQt-builder-1.10[${PYTHON_USEDEP}]
+	>=dev-python/sip-6.2[${PYTHON_USEDEP}]
+	dev-qt/qtcore:5
+"
+
+src_prepare() {
+	default
+	mv pyproject{-qt5,}.toml || die
+}
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			sip-build
+			--verbose
+			--build-dir="${BUILD_DIR}"
+			--scripts-dir="$(python_get_scriptdir)"
+			--qmake="$(qt5_get_bindir)"/qmake
+			--no-make
+			$(usev debug '--debug --qml-debug --tracing')
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Run eqmake to respect toolchain and build flags
+		run_in_build_dir eqmake5 -recursive ${MY_PN}.pro
+	}
+	python_foreach_impl configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+}