dev-python/grpcio: bump to 1.25.0

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/grpcio/grpcio-1.25.0.ebuild b/dev-python/grpcio/grpcio-1.25.0.ebuild
new file mode 100644
index 000000000000..bcf535535b98
--- /dev/null
+++ b/dev-python/grpcio/grpcio-1.25.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="High-performance RPC framework (python libraries)"
+HOMEPAGE="https://grpc.io"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND=">=dev-libs/openssl-1.0.2:0=[-bindist]
+	>=dev-python/cython-0.28.3[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	net-dns/c-ares:=
+	!<net-libs/grpc-1.16.0[python]
+	sys-libs/zlib:=
+	virtual/python-enum34[${PYTHON_USEDEP}]
+	virtual/python-futures[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+python_configure_all() {
+	export GRPC_PYTHON_DISABLE_LIBC_COMPATIBILITY=1
+	export GRPC_PYTHON_BUILD_SYSTEM_CARES=1
+	export GRPC_PYTHON_BUILD_SYSTEM_OPENSSL=1
+	export GRPC_PYTHON_BUILD_SYSTEM_ZLIB=1
+	export GRPC_PYTHON_BUILD_WITH_CYTHON=1
+	export GRPC_PYTHON_BUILD_EXT_COMPILER_JOBS="$(makeopts_jobs)"
+}