proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

3 files changed, 91 insertions, 0 deletions

diff --git a/dev-python/dbus-python/Manifest b/dev-python/dbus-python/Manifest
new file mode 100644
index 000000000000..67bd685a80d5
--- /dev/null
+++ b/dev-python/dbus-python/Manifest
@@ -0,0 +1 @@
+DIST dbus-python-1.2.0.tar.gz 602426 SHA256 e12c6c8b2bf3a9302f75166952cbe41d6b38c3441bbc6767dbd498942316c6df SHA512 013b23e08fa1ed43f53a756587fefbc9770f7c51e93510e555acbd77230b7200693419bba9a69680d790bbaf123f4a195afa38b3eee1143da950fee0b5130bce WHIRLPOOL 2b505646c21afd6238f32cda7aaf5f4b770d3c82b0d5c2c254f044729d6e06d3eab89cf816dbd22e96b8d8e1550297521dcb49fc90bb4825fdafd12d5beba5ee
diff --git a/dev-python/dbus-python/dbus-python-1.2.0-r1.ebuild b/dev-python/dbus-python/dbus-python-1.2.0-r1.ebuild
new file mode 100644
index 000000000000..8b025358fb72
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-1.2.0-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit autotools eutils python-r1
+
+DESCRIPTION="Python bindings for the D-Bus messagebus"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/DBusBindings http://dbus.freedesktop.org/doc/dbus-python/"
+SRC_URI="http://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~m68k-mint"
+IUSE="doc examples test"
+# API docs generated with epydoc, which is python2-only
+REQUIRED_USE="doc? ( python_targets_python2_7 )"
+
+RDEPEND=">=dev-libs/dbus-glib-0.100:=
+	>=sys-apps/dbus-1.6:=
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		dev-python/docutils[python_targets_python2_7?]
+		=dev-python/epydoc-3*[python_targets_python2_7?] )
+	test? ( dev-python/pygobject:3[${PYTHON_USEDEP}] )"
+
+src_prepare() {
+	# Update py-compile, bug 529502.
+	eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	configuring() {
+		# epydoc is python2-only, bug #447642
+		local apidocs=--disable-api-docs
+		[[ ${EPYTHON/.*} = "python2" ]] && apidocs=$(use_enable doc api-docs)
+
+		econf \
+			--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+			--disable-html-docs \
+			${apidocs} \
+			PYTHON_LIBS="$(python-config --ldflags)"
+		# configure assumes that ${PYTHON}-config executable exists :/
+	}
+	python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installing() {
+		default
+		[[ ${EPYTHON/.*} = "python2" ]] && use doc && dohtml -r api/*
+	}
+	python_foreach_impl run_in_build_dir installing
+	prune_libtool_files --modules
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}
+
+run_in_build_dir() {
+	pushd "${BUILD_DIR}" > /dev/null || die
+	"$@"
+	popd > /dev/null
+}
diff --git a/dev-python/dbus-python/metadata.xml b/dev-python/dbus-python/metadata.xml
new file mode 100644
index 000000000000..1f701e5bb782
--- /dev/null
+++ b/dev-python/dbus-python/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>python</herd>
+  <herd>freedesktop</herd>
+  <maintainer>
+    <email>freedesktop-bugs@gentoo.org</email>
+  </maintainer>
+</pkgmetadata>