dev-libs/apache-arrow: Bump to 18.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 128 insertions, 0 deletions

diff --git a/dev-libs/apache-arrow/Manifest b/dev-libs/apache-arrow/Manifest
index b72958532eff..1df70652cc04 100644
--- a/dev-libs/apache-arrow/Manifest
+++ b/dev-libs/apache-arrow/Manifest
@@ -1,3 +1,4 @@
 DIST apache-arrow-18.0.0.tar.gz 19113236 BLAKE2B c358f8e61155432540a4002c6dfba7a3763d934a43eddae0a9a6f98bb26879df51e3cdcc64db6dd684ffde2ef8ef6dcff8906355b5769f71afae907aa1e920c5 SHA512 4df30ab5561da695eaa864422626b9898555d86ca56835c3b8a8ca93a1dbaf081582bb36e2440d1daf7e1dd48c76941f1152a4f25ce0dbcc1c2abe244a00c05e
+DIST apache-arrow-18.1.0.tar.gz 19132388 BLAKE2B 4a8c60d8a5dcf2b8ac4e2ae3a7f555dd0604d5ccc4b72ba317f18e16e75725b24553050fe88a02f382b0581310f20d0b795133b243f2851fa0e8d3801a839358 SHA512 7249c03a6097bc64fb0092143e4d4aaef3227565147e6254f026ddd504177c8dd565a184a0df39743dc989070dc3785e5b66f738c8e310ed9c982b61c2ec4914
 DIST arrow-testing-4d209492d514c2d3cb2d392681b9aa00e6d8da1c.tar.gz 3572558 BLAKE2B fe5b6a46babbde8e2becefea09fecf090201a49faa7d4ee2f44b0bb4da42c344b37564999d32fdbd54a81a56c33fbde9b2d9d2fa664bf127cb5661e845fb6229 SHA512 6758ad936e1eeb2c5dd2b4b40fe90822a48a4ce67ee4d36657c168e1db5d9a17c092f4cf571b13d56b568a773515385441874d1ea36a1f6e5b15a99f67176fa3
 DIST parquet-testing-cb7a9674142c137367bf75a01b79c6e214a73199.tar.gz 1068025 BLAKE2B 0fdd12d04108b27b17564c60ca36e751453f5d74cfbbe3a076e8befa1696aa0f093e2d1a5eacb99e69a98deda502930ba79b8329403af1e8b9d696e6617c6075 SHA512 dd221d9d59442cebb7158d7cf769d6e5323416bfcde2852eee37a26ff089bc04ea10b9ae7158a37d8694c10469d77c7d251d0dd2549596a7b3899d9c39b45997
diff --git a/dev-libs/apache-arrow/apache-arrow-18.1.0.ebuild b/dev-libs/apache-arrow/apache-arrow-18.1.0.ebuild
new file mode 100644
index 000000000000..6a952147632e
--- /dev/null
+++ b/dev-libs/apache-arrow/apache-arrow-18.1.0.ebuild
@@ -0,0 +1,127 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+# arrow.git: testing
+ARROW_DATA_GIT_HASH=4d209492d514c2d3cb2d392681b9aa00e6d8da1c
+# arrow.git: cpp/submodules/parquet-testing
+PARQUET_DATA_GIT_HASH=cb7a9674142c137367bf75a01b79c6e214a73199
+
+DESCRIPTION="A cross-language development platform for in-memory data."
+HOMEPAGE="
+	https://arrow.apache.org/
+	https://github.com/apache/arrow/
+"
+SRC_URI="
+	mirror://apache/arrow/arrow-${PV}/${P}.tar.gz
+	test? (
+		https://github.com/apache/parquet-testing/archive/${PARQUET_DATA_GIT_HASH}.tar.gz
+			-> parquet-testing-${PARQUET_DATA_GIT_HASH}.tar.gz
+		https://github.com/apache/arrow-testing/archive/${ARROW_DATA_GIT_HASH}.tar.gz
+			-> arrow-testing-${ARROW_DATA_GIT_HASH}.tar.gz
+	)
+"
+S="${WORKDIR}/${P}/cpp"
+
+LICENSE="Apache-2.0"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~riscv ~s390 ~x86"
+IUSE="
+	+brotli bzip2 compute dataset +json lz4 +parquet re2 +snappy ssl
+	test zlib zstd
+"
+REQUIRED_USE="
+	test? (
+		json
+		parquet? ( zstd )
+	)
+	ssl? ( json )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	brotli? ( app-arch/brotli:= )
+	bzip2? ( app-arch/bzip2:= )
+	compute? ( dev-libs/libutf8proc:= )
+	dataset? (
+		dev-libs/libutf8proc:=
+	)
+	lz4? ( app-arch/lz4:= )
+	parquet? (
+		dev-libs/libutf8proc:=
+		dev-libs/thrift:=
+		ssl? ( dev-libs/openssl:= )
+	)
+	re2? ( dev-libs/re2:= )
+	snappy? ( app-arch/snappy:= )
+	zlib? ( sys-libs/zlib:= )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="
+	${RDEPEND}
+	dev-cpp/xsimd
+	>=dev-libs/boost-1.81.0
+	json? ( dev-libs/rapidjson )
+	test? (
+		dev-cpp/gflags
+		dev-cpp/gtest
+	)
+"
+
+src_prepare() {
+	# use Gentoo CXXFLAGS, specify docdir at src_configure.
+	sed -i \
+		-e '/SetupCxxFlags/d' \
+		-e '/set(ARROW_DOC_DIR.*)/d' \
+		CMakeLists.txt \
+		|| die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DARROW_BUILD_STATIC=OFF
+		-DARROW_BUILD_TESTS=$(usex test)
+		-DARROW_COMPUTE=$(usex compute)
+		-DARROW_CSV=ON
+		-DARROW_DATASET=$(usex dataset)
+		-DARROW_DEPENDENCY_SOURCE=SYSTEM
+		-DARROW_DOC_DIR=share/doc/${PF}
+		-DARROW_FILESYSTEM=ON
+		-DARROW_HDFS=ON
+		-DARROW_JEMALLOC=OFF
+		-DARROW_JSON=$(usex json)
+		-DARROW_PARQUET=$(usex parquet)
+		-DPARQUET_REQUIRE_ENCRYPTION=$(usex ssl)
+		-DARROW_USE_CCACHE=OFF
+		-DARROW_USE_SCCACHE=OFF
+		-DARROW_WITH_BROTLI=$(usex brotli)
+		-DARROW_WITH_BZ2=$(usex bzip2)
+		-DARROW_WITH_LZ4=$(usex lz4)
+		-DARROW_WITH_RE2=$(usex re2)
+		-DARROW_WITH_SNAPPY=$(usex snappy)
+		-DARROW_WITH_ZLIB=$(usex zlib)
+		-DARROW_WITH_ZSTD=$(usex zstd)
+		-DCMAKE_CXX_STANDARD=17
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local -x PARQUET_TEST_DATA="${WORKDIR}/parquet-testing-${PARQUET_DATA_GIT_HASH}/data"
+	local -x ARROW_TEST_DATA="${WORKDIR}/arrow-testing-${ARROW_DATA_GIT_HASH}/data"
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+	if use test; then
+		cd "${D}"/usr/$(get_libdir) || die
+		rm -r cmake/ArrowTesting || die
+		rm libarrow_testing* || die
+		rm pkgconfig/arrow-testing.pc || die
+	fi
+}