dev-lang/spidermonkey: drop 91.5.0

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 0 insertions, 425 deletions

diff --git a/dev-lang/spidermonkey/Manifest b/dev-lang/spidermonkey/Manifest
index 7b7f458d9eb3..c4990f42aa08 100644
--- a/dev-lang/spidermonkey/Manifest
+++ b/dev-lang/spidermonkey/Manifest
@@ -2,7 +2,6 @@ DIST firefox-68.0-patches-15.tar.xz 16060 BLAKE2B f9e6cd58ea51bed1af90a9d30fd551
 DIST firefox-68.12.0esr.source.tar.xz 313856956 BLAKE2B eeaa4acc9fabf15ec1b313170a30cee8e1fc10a8b08512b915b83b7d6a81c09b365733ed94638bd434864fd7b0cb8cbf1bc2e43441be69e31117e8e6a099234c SHA512 839b02422e4c87bdb12e0995cd35ca8c1996f3fba00bbb46b419e46b67df5ec48a264cb14632db777ce29166ee4fdcb06e2ee3ce847e64328c58c9a2f9129f4c
 DIST firefox-78.15.0esr.source.tar.xz 330819568 BLAKE2B dc8785613c2f72c55d484642c89c2545765a9efbd609bc7c2cf57b4a3a06a2ea22e6959e42b5b8af867db782e8b2097a67dec858796b744e47008a8e575e2316 SHA512 ac3de735b246ce4f0e1619cd2664321ffa374240ce6843e785d79a350dc30c967996bbcc5e3b301cb3d822ca981cbea116758fc4122f1738d75ddfd1165b6378
 DIST firefox-78esr-patches-19.tar.xz 88424 BLAKE2B fdc7bf8f28b3e799551a70f1cec7a695f52c4712f3b28733648fcd7dac5a599613f4c3d2cfa169266dc62b65619b7f28c0e06d32317adb8ec0056ca79c87e9f6 SHA512 3c81dadc9bf74207c4e361605127ef6141d77700c5c54f1f9cd5ad3be13df9f73c6eec2f51d779558e4bdad1e7395c6aa8943a93415bd1786d461042bc03550a
-DIST firefox-91.5.0esr.source.tar.xz 381371300 BLAKE2B 21b25ded0d0541d2a5c0964ffe5e28a3b238b5dac1c0969383f8a41cb6a0fff8522c4ccfbd1cd309a5c52be9377ca9af446949dd3d9923cf36ce0e6603ff520a SHA512 1712415b6b73c6a21edfefc39eaba5fcbbca54032f78627c0005d291501d16ef4daffb8b9a160d1d5361113ceba04eb5ddb21d903e3dd8d58838aa9596f2d781
 DIST firefox-91.5.1esr.source.tar.xz 388976720 BLAKE2B 5ade6b402af1ad14438eabefe3d8249b8e0125968b7d6950f29747ff3a41f9f1b02c52a417756b07b68bacdde43549768d1b999b15ecdca237be9c0363d13b0c SHA512 26239e7a94b79f1e24a6667d7cf1c398d75992e8850144affbc5d3f34f04b91f0c9b020cab662b2cd4927924839ff2ddd2f3605c537bb5494fd9ac0d951b14fa
 DIST firefox-91esr-patches-04.tar.xz 17460 BLAKE2B 305d8b0bc8a4115a76e459afd8bc7987bdde2e76d4564faf664a92a4c6a95c975ce599c5ddde9bdafc3c37ca5c8758e0ef815364d0ce4dd5fd452ddae73a77eb SHA512 6073b31bb898fe61d72435b11deacb5e93a1744227e4704bb3012e0cb363792f3a965d72e7769c4aae3a25f0c81247b287ce145c81bbd0a87470a5438fede11e
 DIST js185-1.0.0.tar.gz 6164605 BLAKE2B 76a37f0ceae05d3475853875bd0ce4be6e525e4114816f8f281ea6fc6b60a71060975a0fa1cb843f57ad1e2f842dfb26b24244fa0fd6c20f6ae2ebbe430f70be SHA512 2af7122a7c7007fd7b6668776fe1222515a810b3e43bbf0f76b8f94e1ef406ffd3fb5ccec393021b00274c05b38a77235bc8d6886994c56762fcaf0aa7cf6718
diff --git a/dev-lang/spidermonkey/spidermonkey-91.5.0.ebuild b/dev-lang/spidermonkey/spidermonkey-91.5.0.ebuild
deleted file mode 100644
index f2c8b9767f6c..000000000000
--- a/dev-lang/spidermonkey/spidermonkey-91.5.0.ebuild
+++ /dev/null
@@ -1,424 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="7"
-
-# Patch version
-FIREFOX_PATCHSET="firefox-91esr-patches-04.tar.xz"
-SPIDERMONKEY_PATCHSET="spidermonkey-91-patches-02j.tar.xz"
-
-LLVM_MAX_SLOT=13
-
-PYTHON_COMPAT=( python3_{8..10} )
-PYTHON_REQ_USE="ssl"
-
-WANT_AUTOCONF="2.1"
-
-inherit autotools check-reqs flag-o-matic llvm prefix python-any-r1 toolchain-funcs
-
-MY_PN="mozjs"
-MY_PV="${PV/_pre*}" # Handle Gentoo pre-releases
-
-MY_MAJOR=$(ver_cut 1)
-
-MOZ_ESR=yes
-
-MOZ_PV=${PV}
-MOZ_PV_SUFFIX=
-if [[ ${PV} =~ (_(alpha|beta|rc).*)$ ]] ; then
-	MOZ_PV_SUFFIX=${BASH_REMATCH[1]}
-
-	# Convert the ebuild version to the upstream Mozilla version
-	MOZ_PV="${MOZ_PV/_alpha/a}" # Handle alpha for SRC_URI
-	MOZ_PV="${MOZ_PV/_beta/b}"  # Handle beta for SRC_URI
-	MOZ_PV="${MOZ_PV%%_rc*}"    # Handle rc for SRC_URI
-fi
-
-if [[ -n ${MOZ_ESR} ]] ; then
-	# ESR releases have slightly different version numbers
-	MOZ_PV="${MOZ_PV}esr"
-fi
-
-MOZ_PN="firefox"
-MOZ_P="${MOZ_PN}-${MOZ_PV}"
-MOZ_PV_DISTFILES="${MOZ_PV}${MOZ_PV_SUFFIX}"
-MOZ_P_DISTFILES="${MOZ_PN}-${MOZ_PV_DISTFILES}"
-
-MOZ_SRC_BASE_URI="https://archive.mozilla.org/pub/${MOZ_PN}/releases/${MOZ_PV}"
-
-if [[ ${PV} == *_rc* ]] ; then
-	MOZ_SRC_BASE_URI="https://archive.mozilla.org/pub/${MOZ_PN}/candidates/${MOZ_PV}-candidates/build${PV##*_rc}"
-fi
-
-PATCH_URIS=(
-	https://dev.gentoo.org/~{juippis,polynomial-c,whissi}/mozilla/patchsets/${FIREFOX_PATCHSET}
-	https://dev.gentoo.org/~{juippis,polynomial-c,whissi}/mozilla/patchsets/${SPIDERMONKEY_PATCHSET}
-)
-
-SRC_URI="${MOZ_SRC_BASE_URI}/source/${MOZ_P}.source.tar.xz -> ${MOZ_P_DISTFILES}.source.tar.xz
-	${PATCH_URIS[@]}"
-
-DESCRIPTION="SpiderMonkey is Mozilla's JavaScript engine written in C and C++"
-HOMEPAGE="https://spidermonkey.dev https://firefox-source-docs.mozilla.org/js/index.html "
-
-KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc64 ~riscv ~s390 ~x86"
-
-SLOT="91"
-LICENSE="MPL-2.0"
-IUSE="clang cpu_flags_arm_neon debug +jit lto test"
-
-#RESTRICT="test"
-RESTRICT="!test? ( test )"
-
-BDEPEND="${PYTHON_DEPS}
-	virtual/rust
-	virtual/pkgconfig
-	test? (
-		$(python_gen_any_dep 'dev-python/six[${PYTHON_USEDEP}]')
-	)
-	|| (
-		(
-			sys-devel/llvm:13
-			clang? (
-				sys-devel/clang:13
-				lto? ( =sys-devel/lld-13* )
-			)
-		)
-		(
-			sys-devel/llvm:12
-			clang? (
-				sys-devel/clang:12
-				lto? ( =sys-devel/lld-12* )
-			)
-		)
-		(
-			sys-devel/llvm:11
-			clang? (
-				sys-devel/clang:11
-				lto? ( =sys-devel/lld-11* )
-			)
-		)
-		(
-			sys-devel/llvm:10
-			clang? (
-				sys-devel/clang:10
-				lto? ( =sys-devel/lld-10* )
-			)
-		)
-	)"
-DEPEND=">=dev-libs/icu-69.1:=
-	dev-libs/nspr
-	sys-libs/readline:0=
-	sys-libs/zlib"
-RDEPEND="${DEPEND}"
-
-S="${WORKDIR}/firefox-${MY_PV}/js/src"
-
-llvm_check_deps() {
-	if ! has_version -b "sys-devel/llvm:${LLVM_SLOT}" ; then
-		einfo "sys-devel/llvm:${LLVM_SLOT} is missing! Cannot use LLVM slot ${LLVM_SLOT} ..." >&2
-		return 1
-	fi
-
-	if use clang ; then
-		if ! has_version -b "sys-devel/clang:${LLVM_SLOT}" ; then
-			einfo "sys-devel/clang:${LLVM_SLOT} is missing! Cannot use LLVM slot ${LLVM_SLOT} ..." >&2
-			return 1
-		fi
-
-		if use lto ; then
-			if ! has_version -b "=sys-devel/lld-${LLVM_SLOT}*" ; then
-				einfo "=sys-devel/lld-${LLVM_SLOT}* is missing! Cannot use LLVM slot ${LLVM_SLOT} ..." >&2
-				return 1
-			fi
-		fi
-	fi
-
-	einfo "Using LLVM slot ${LLVM_SLOT} to build" >&2
-}
-
-python_check_deps() {
-	if use test ; then
-		has_version "dev-python/six[${PYTHON_USEDEP}]"
-	fi
-}
-
-pkg_pretend() {
-	if use test ; then
-		CHECKREQS_DISK_BUILD="7600M"
-	else
-		CHECKREQS_DISK_BUILD="6400M"
-	fi
-
-	check-reqs_pkg_pretend
-}
-
-pkg_setup() {
-	if [[ ${MERGE_TYPE} != binary ]] ; then
-		if use test ; then
-			CHECKREQS_DISK_BUILD="7600M"
-		else
-			CHECKREQS_DISK_BUILD="6400M"
-		fi
-
-		check-reqs_pkg_setup
-
-		llvm_pkg_setup
-
-		if use clang && use lto ; then
-			local version_lld=$(ld.lld --version 2>/dev/null | awk '{ print $2 }')
-			[[ -n ${version_lld} ]] && version_lld=$(ver_cut 1 "${version_lld}")
-			[[ -z ${version_lld} ]] && die "Failed to read ld.lld version!"
-
-			# temp fix for https://bugs.gentoo.org/768543
-			# we can assume that rust 1.{49,50}.0 always uses llvm 11
-			local version_rust=$(rustc -Vv 2>/dev/null | grep -F -- 'release:' | awk '{ print $2 }')
-			[[ -n ${version_rust} ]] && version_rust=$(ver_cut 1-2 "${version_rust}")
-			[[ -z ${version_rust} ]] && die "Failed to read version from rustc!"
-
-			if ver_test "${version_rust}" -ge "1.49" && ver_test "${version_rust}" -le "1.50" ; then
-				local version_llvm_rust="11"
-			else
-				local version_llvm_rust=$(rustc -Vv 2>/dev/null | grep -F -- 'LLVM version:' | awk '{ print $3 }')
-				[[ -n ${version_llvm_rust} ]] && version_llvm_rust=$(ver_cut 1 "${version_llvm_rust}")
-				[[ -z ${version_llvm_rust} ]] && die "Failed to read used LLVM version from rustc!"
-			fi
-
-			if ver_test "${version_lld}" -ne "${version_llvm_rust}" ; then
-				eerror "Rust is using LLVM version ${version_llvm_rust} but ld.lld version belongs to LLVM version ${version_lld}."
-				eerror "You will be unable to link ${CATEGORY}/${PN}. To proceed you have the following options:"
-				eerror "  - Manually switch rust version using 'eselect rust' to match used LLVM version"
-				eerror "  - Switch to dev-lang/rust[system-llvm] which will guarantee matching version"
-				eerror "  - Build ${CATEGORY}/${PN} without USE=lto"
-				die "LLVM version used by Rust (${version_llvm_rust}) does not match with ld.lld version (${version_lld})!"
-			fi
-		fi
-
-		python-any-r1_pkg_setup
-
-		# Build system is using /proc/self/oom_score_adj, bug #604394
-		addpredict /proc/self/oom_score_adj
-
-		if ! mountpoint -q /dev/shm ; then
-			# If /dev/shm is not available, configure is known to fail with
-			# a traceback report referencing /usr/lib/pythonN.N/multiprocessing/synchronize.py
-			ewarn "/dev/shm is not mounted -- expect build failures!"
-		fi
-
-		# Ensure we use C locale when building, bug #746215
-		export LC_ALL=C
-	fi
-}
-
-src_prepare() {
-	pushd ../.. &>/dev/null || die
-
-	use lto && rm -v "${WORKDIR}"/firefox-patches/*-LTO-Only-enable-LTO-*.patch
-
-	eapply "${WORKDIR}"/firefox-patches
-	eapply "${WORKDIR}"/spidermonkey-patches
-
-	default
-
-	# sed-in toolchain prefix
-	sed -i \
-		-e "s/objdump/${CHOST}-objdump/" \
-		python/mozbuild/mozbuild/configure/check_debug_ranges.py \
-		|| die "sed failed to set toolchain prefix"
-
-	# use prefix shell in wrapper linker scripts, bug #789660
-	hprefixify "${S}"/../../build/cargo-{,host-}linker
-
-	einfo "Removing pre-built binaries ..."
-	find third_party -type f \( -name '*.so' -o -name '*.o' \) -print -delete || die
-
-	MOZJS_BUILDDIR="${WORKDIR}/build"
-	mkdir "${MOZJS_BUILDDIR}" || die
-
-	popd &>/dev/null || die
-	eautoconf
-}
-
-src_configure() {
-	# Show flags set at the beginning
-	einfo "Current CFLAGS:    ${CFLAGS}"
-	einfo "Current CXXFLAGS:  ${CXXFLAGS}"
-	einfo "Current LDFLAGS:   ${LDFLAGS}"
-	einfo "Current RUSTFLAGS: ${RUSTFLAGS}"
-
-	local have_switched_compiler=
-	if use clang && ! tc-is-clang ; then
-		# Force clang
-		einfo "Enforcing the use of clang due to USE=clang ..."
-		have_switched_compiler=yes
-		AR=llvm-ar
-		CC=${CHOST}-clang
-		CXX=${CHOST}-clang++
-		NM=llvm-nm
-		RANLIB=llvm-ranlib
-	elif ! use clang && ! tc-is-gcc ; then
-		# Force gcc
-		have_switched_compiler=yes
-		einfo "Enforcing the use of gcc due to USE=-clang ..."
-		AR=gcc-ar
-		CC=${CHOST}-gcc
-		CXX=${CHOST}-g++
-		NM=gcc-nm
-		RANLIB=gcc-ranlib
-	fi
-
-	if [[ -n "${have_switched_compiler}" ]] ; then
-		# Because we switched active compiler we have to ensure
-		# that no unsupported flags are set
-		strip-unsupported-flags
-	fi
-
-	# Ensure we use correct toolchain
-	export HOST_CC="$(tc-getBUILD_CC)"
-	export HOST_CXX="$(tc-getBUILD_CXX)"
-	tc-export CC CXX LD AR NM OBJDUMP RANLIB PKG_CONFIG
-
-	cd "${MOZJS_BUILDDIR}" || die
-
-	# ../python/mach/mach/mixin/process.py fails to detect SHELL
-	export SHELL="${EPREFIX}/bin/bash"
-
-	local -a myeconfargs=(
-		--host="${CBUILD:-${CHOST}}"
-		--target="${CHOST}"
-		--disable-ctype
-		--disable-jemalloc
-		--disable-optimize
-		--disable-smoosh
-		--disable-strip
-		--enable-readline
-		--enable-release
-		--enable-shared-js
-		--with-intl-api
-		--with-system-icu
-		--with-system-nspr
-		--with-system-zlib
-		--with-toolchain-prefix="${CHOST}-"
-		$(use_enable debug)
-		$(use_enable jit)
-		$(use_enable test tests)
-	)
-
-	if ! use x86 && [[ ${CHOST} != armv*h* ]] ; then
-		myeconfargs+=( --enable-rust-simd )
-	fi
-
-	# Modifications to better support ARM, bug 717344
-	if use cpu_flags_arm_neon ; then
-		myeconfargs+=( --with-fpu=neon )
-
-		if ! tc-is-clang ; then
-			# thumb options aren't supported when using clang, bug 666966
-			myeconfargs+=( --with-thumb=yes )
-			myeconfargs+=( --with-thumb-interwork=no )
-		fi
-	fi
-
-	# Tell build system that we want to use LTO
-	if use lto ; then
-		if use clang ; then
-			myeconfargs+=( --enable-linker=lld )
-			myeconfargs+=( --enable-lto=cross )
-		else
-			myeconfargs+=( --enable-linker=bfd )
-			myeconfargs+=( --enable-lto )
-		fi
-	fi
-
-	# LTO flag was handled via configure
-	filter-flags '-flto*'
-
-	if tc-is-gcc ; then
-		if ver_test $(gcc-fullversion) -ge 10 ; then
-			einfo "Forcing -fno-tree-loop-vectorize to workaround GCC bug, see bug 758446 ..."
-			append-cxxflags -fno-tree-loop-vectorize
-		fi
-	fi
-
-	export MACH_USE_SYSTEM_PYTHON=1
-	export PIP_NO_CACHE_DIR=off
-
-	# Show flags we will use
-	einfo "Build CFLAGS:    ${CFLAGS}"
-	einfo "Build CXXFLAGS:  ${CXXFLAGS}"
-	einfo "Build LDFLAGS:   ${LDFLAGS}"
-	einfo "Build RUSTFLAGS: ${RUSTFLAGS}"
-
-	# Forcing system-icu allows us to skip patching bundled ICU for PPC
-	# and other minor arches
-	ECONF_SOURCE="${S}" \
-		econf \
-		${myeconfargs[@]} \
-		XARGS="${EPREFIX}/usr/bin/xargs"
-}
-
-src_compile() {
-	cd "${MOZJS_BUILDDIR}" || die
-	default
-}
-
-src_test() {
-	if "${MOZJS_BUILDDIR}/js/src/js" -e 'print("Hello world!")'; then
-		einfo "Smoke-test successful, continuing with full test suite"
-	else
-		die "Smoke-test failed: did interpreter initialization fail?"
-	fi
-
-	cp "${FILESDIR}"/spidermonkey-91-known-test-failures.txt "${T}"/known_failures.list || die
-
-	if use x86 ; then
-		echo "non262/Date/timeclip.js" >> "${T}"/known_failures.list
-		echo "test262/built-ins/Number/prototype/toPrecision/return-values.js" >> "${T}"/known_failures.list
-		echo "test262/language/types/number/S8.5_A2.1.js" >> "${T}"/known_failures.list
-		echo "test262/language/types/number/S8.5_A2.2.js" >> "${T}"/known_failures.list
-	fi
-
-	if [[ $(tc-endian) == "big" ]] ; then
-		echo "non262/extensions/clone-errors.js" >> "${T}"/known_failures.list
-		echo "test262/built-ins/Date/UTC/fp-evaluation-order.js" >> "${T}"/known_failures.list
-		echo "test262/built-ins/TypedArray/prototype/set/typedarray-arg-set-values-same-buffer-other-type.js" >> "${T}"/known_failures.list
-	fi
-
-	${EPYTHON} \
-		"${S}"/tests/jstests.py -d -s -t 1800 --wpt=disabled --no-progress \
-		--exclude-file="${T}"/known_failures.list \
-		"${MOZJS_BUILDDIR}"/js/src/js \
-		|| die
-
-	if use jit ; then
-		${EPYTHON} \
-			"${S}"/tests/jstests.py -d -s -t 1800 --wpt=disabled --no-progress \
-			--exclude-file="${T}"/known_failures.list \
-			"${MOZJS_BUILDDIR}"/js/src/js basic \
-			|| die
-	fi
-}
-
-src_install() {
-	cd "${MOZJS_BUILDDIR}" || die
-	default
-
-	# fix soname links
-	pushd "${ED}"/usr/$(get_libdir) &>/dev/null || die
-	mv lib${MY_PN}-${MY_MAJOR}.so lib${MY_PN}-${MY_MAJOR}.so.0.0.0 || die
-	ln -s lib${MY_PN}-${MY_MAJOR}.so.0.0.0 lib${MY_PN}-${MY_MAJOR}.so.0 || die
-	ln -s lib${MY_PN}-${MY_MAJOR}.so.0 lib${MY_PN}-${MY_MAJOR}.so || die
-	popd &>/dev/null || die
-
-	# remove unneeded files
-	rm \
-		"${ED}"/usr/bin/js${MY_MAJOR}-config \
-		"${ED}"/usr/$(get_libdir)/libjs_static.ajs \
-		|| die
-
-	# fix permissions
-	chmod -x \
-		"${ED}"/usr/$(get_libdir)/pkgconfig/*.pc \
-		"${ED}"/usr/include/mozjs-${MY_MAJOR}/js-config.h \
-		|| die
-}