net-misc/kea: fixed version 1.9.9

Signed-off-by: Dennis Lamm <expeditioneer@gentoo.org>
Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Dennis Lamm <expeditioneer@gentoo.org>

1 files changed, 102 insertions, 0 deletions

diff --git a/net-misc/kea/kea-1.9.9-r1.ebuild b/net-misc/kea/kea-1.9.9-r1.ebuild
new file mode 100644
index 000000000000..7875a3f8860b
--- /dev/null
+++ b/net-misc/kea/kea-1.9.9-r1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PV="${PV//_p/-P}"
+MY_PV="${MY_PV/_/-}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="High-performance production grade DHCPv4 & DHCPv6 server"
+HOMEPAGE="http://www.isc.org/kea/"
+
+inherit autotools systemd tmpfiles
+
+if [[ ${PV} = 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/isc-projects/kea.git"
+else
+	SRC_URI="ftp://ftp.isc.org/isc/kea/${MY_P}.tar.gz
+		ftp://ftp.isc.org/isc/kea/${MY_PV}/${MY_P}.tar.gz"
+	[[ "${PV}" == *_beta* ]] || [[ "${PV}" == *_rc* ]] || \
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="ISC BSD SSLeay GPL-2" # GPL-2 only for init script
+SLOT="0"
+IUSE="mysql +openssl postgres +samples"
+
+DEPEND="
+	dev-libs/boost:=
+	dev-cpp/gtest
+	dev-libs/log4cplus
+	mysql? ( dev-db/mysql-connector-c )
+	!openssl? ( dev-libs/botan:2= )
+	openssl? ( dev-libs/openssl:0= )
+	postgres? ( dev-db/postgresql:* )
+"
+RDEPEND="${DEPEND}
+	acct-group/dhcp
+	acct-user/dhcp"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	# Brand the version with Gentoo
+	sed -i \
+		-e "s/AC_INIT(kea,${PV}.*, kea-dev@lists.isc.org)/AC_INIT(kea,${PVR}-gentoo, kea-dev@lists.isc.org)/g" \
+		configure.ac || die
+
+	sed -i \
+		-e '/mkdir -p $(DESTDIR)${runstatedir}\/${PACKAGE_NAME}/d' \
+		Makefile.am || die "Fixing Makefile.am failed"
+
+	sed -i \
+		-e 's#test -f "$dir/lib/libgtest.a"#test -f "$dir/lib64/libgtest.a"#g' \
+		-e 's#test -f "$dir/lib/libgtest.so"#test -f "$dir/lib64/libgtest.so"#g' \
+		-e 's GTEST_LDFLAGS="-L$dir/lib GTEST_LDFLAGS="-L$dir/lib64 g' \
+		m4macros/ax_gtest.m4 || die "fixing gtest detection macro failed"
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-install-configurations
+		--disable-static
+		--enable-perfdhcp
+		--localstatedir="${EPREFIX}/var"
+		--runstatedir="${EPREFIX}/run"
+		--with-gtest=/usr
+		--without-werror
+		$(use_with mysql)
+		$(use_with openssl)
+		$(use_with postgres pgsql)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	newconfd "${FILESDIR}"/${PN}-confd-r1 ${PN}
+	newinitd "${FILESDIR}"/${PN}-initd-r1 ${PN}
+
+	if use samples; then
+		cp "${FILESDIR}"/kea-ctrl-agent.conf "${ED}"/etc/kea/kea-ctrl-agent.conf || die "Could not create kea-ctrl-agent.conf"
+		cp "${FILESDIR}"/kea-ddns-server.conf "${ED}"/etc/kea/kea-ddns-server.conf || die "Could not create kea-ddns-server.conf"
+		cp "${FILESDIR}"/kea-dhcp4.conf "${ED}"/etc/kea/kea-dhcp4.conf || die "Could not create kea kea-dhcp4.conf"
+		cp "${FILESDIR}"/kea-dhcp6.conf "${ED}"/etc/kea/kea-dhcp6.conf || die "Could not create kea-dhcp6.conf"
+	fi
+
+	systemd_dounit "${FILESDIR}/${PN}-ctrl-agent.service"
+	systemd_dounit "${FILESDIR}/${PN}-dhcp4-server.service"
+	systemd_dounit "${FILESDIR}/${PN}-dhcp6-server.service"
+	systemd_dounit "${FILESDIR}/${PN}-dhcp-ddns-server.service"
+
+	newtmpfiles "${FILESDIR}"/${PN}.tmpfiles.conf ${PN}.conf
+
+	keepdir /var/lib/${PN} /var/log
+	find "${ED}" -type f -name "*.la" -delete || die
+}