blob: 0b5fb4b044b83619b654af84ee6cfdca9d0f209b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/cheese/cheese-3.12.1.ebuild,v 1.1 2014/04/27 17:37:39 eva Exp $
EAPI="5"
GCONF_DEBUG="no"
VALA_MIN_API_VERSION="0.24"
inherit gnome2 vala virtualx
DESCRIPTION="A cheesy program to take pictures and videos from your webcam"
HOMEPAGE="http://projects.gnome.org/cheese/"
LICENSE="GPL-2+"
SLOT="0/7" # subslot = libcheese soname version
IUSE="+introspection test"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
# using clutter-gst-2.0.0 results in GLSL errors; bug #478702
COMMON_DEPEND="
>=dev-libs/glib-2.39.90:2
>=x11-libs/gtk+-3.10:3[introspection?]
>=x11-libs/cairo-1.10:=
>=x11-libs/pango-1.28.0
>=gnome-base/gnome-desktop-2.91.6:3=
>=gnome-base/librsvg-2.32.0:2
>=media-libs/libcanberra-0.26[gtk3]
>=media-libs/clutter-1.13.2:1.0[introspection?]
>=media-libs/clutter-gtk-0.91.8:1.0
>=media-libs/clutter-gst-2.0.6:2.0
media-libs/cogl:1.0=[introspection?]
media-video/gnome-video-effects
x11-libs/gdk-pixbuf:2[jpeg,introspection?]
x11-libs/libX11
x11-libs/libXtst
media-libs/gstreamer:1.0[introspection?]
media-libs/gst-plugins-base:1.0[introspection?,ogg,pango,theora,vorbis,X]
>=virtual/udev-171:=[gudev]
introspection? ( >=dev-libs/gobject-introspection-0.6.7 )
"
RDEPEND="${COMMON_DEPEND}
media-libs/gst-plugins-bad:1.0
media-libs/gst-plugins-good:1.0
media-plugins/gst-plugins-jpeg:1.0
media-plugins/gst-plugins-v4l2:1.0
media-plugins/gst-plugins-vpx:1.0
"
DEPEND="${COMMON_DEPEND}
$(vala_depend)
app-text/docbook-xml-dtd:4.3
app-text/yelp-tools
dev-libs/libxml2:2
>=dev-util/gtk-doc-am-1.14
>=dev-util/intltool-0.50
virtual/pkgconfig
x11-proto/xf86vidmodeproto
test? ( dev-libs/glib:2[utils] )
"
src_prepare() {
# FIXME: looks like a regression from an underlying library
sed -e 's|\(g_test_add_func.*photo_path.*;\)|/*\1*/|' \
-e 's|\(g_test_add_func.*video_path.*;\)|/*\1*/|' \
-i "${S}"/tests/test-libcheese.c || die
vala_src_prepare
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
GST_INSPECT=$(type -P true) \
$(use_enable introspection) \
--disable-lcov \
--disable-static \
ITSTOOL=$(type -P true)
}
src_compile() {
# Clutter-related sandbox violations when USE="doc introspection" and
# FEATURES="-userpriv" (see bug #385917).
unset DISPLAY
gnome2_src_compile
}
src_test() {
Xemake check
}
|
GitWeb