blob: c65a2555a406e70915f4eda0846dc3b3badf076c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/gd/gd-2.0.35-r4.ebuild,v 1.3 2014/06/15 01:00:02 vapier Exp $
EAPI="5"
inherit autotools eutils multilib-minimal
DESCRIPTION="A graphics library for fast image creation"
HOMEPAGE="http://libgd.org/ http://www.boutell.com/gd/"
SRC_URI="http://libgd.org/releases/${P}.tar.bz2"
LICENSE="gd IJG HPND BSD"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
IUSE="fontconfig jpeg png static-libs truetype xpm zlib"
RDEPEND="fontconfig? ( media-libs/fontconfig[${MULTILIB_USEDEP}] )
jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
png? ( >=media-libs/libpng-1.2:0[${MULTILIB_USEDEP}] )
truetype? ( >=media-libs/freetype-2.1.5[${MULTILIB_USEDEP}] )
xpm? ( x11-libs/libXpm[${MULTILIB_USEDEP}] x11-libs/libXt[${MULTILIB_USEDEP}] )
zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
virtual/pkgconfig[${MULTILIB_USEDEP}]"
MULTILIB_CHOST_TOOLS=(
/usr/bin/gdlib-config
)
src_prepare() {
epatch "${FILESDIR}"/${P}-libpng14.patch #305101
epatch "${FILESDIR}"/${P}-maxcolors.patch #292130
epatch "${FILESDIR}"/${P}-fontconfig.patch #363367
epatch "${FILESDIR}"/${P}-libpng-pkg-config.patch
# Avoid programs we never install
local make_sed=( -e '/^noinst_PROGRAMS/s:noinst:check:' )
use png || make_sed+=( -e '/_PROGRAMS/s:(gdparttopng|gdtopng|gd2topng|pngtogd|pngtogd2|webpng)::g' )
use zlib || make_sed+=( -e '/_PROGRAMS/s:(gd2topng|gd2copypal|gd2togif|giftogd2|gdparttopng|pngtogd2)::g' )
sed -i -r "${make_sed[@]}" Makefile.am || die
# bug 466996
sed -i 's/AM_PROG_CC_STDC/AC_PROG_CC/' configure.ac || die
cat <<-EOF > acinclude.m4
m4_ifndef([AM_ICONV],[m4_define([AM_ICONV],[AC_SUBST(LIBICONV)])])
EOF
eautoreconf
}
multilib_src_configure() {
export ac_cv_lib_z_deflate=$(usex zlib)
# we aren't actually {en,dis}abling X here ... the configure
# script uses it just to add explicit -I/-L paths which we
# don't care about on Gentoo systems.
ECONF_SOURCE=${S} \
econf \
--without-x \
$(use_enable static-libs static) \
$(use_with fontconfig) \
$(use_with png) \
$(use_with truetype freetype) \
$(use_with jpeg) \
$(use_with xpm)
}
multilib_src_install_all() {
dodoc INSTALL README*
dohtml -r ./
prune_libtool_files
}
|
GitWeb
