dev-util/suse-build/suse-build-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/suse-build/suse-build-9999.ebuild,v 1.8 2013/07/16 13:52:35 scarabeus Exp $

EAPI=5

EGIT_REPO_URI="git://github.com/openSUSE/obs-build.git"

if [[ "${PV}" == "9999" ]]; then
	EXTRA_ECLASS="git-2"
else
	OBS_PACKAGE="build"
	OBS_PROJECT="openSUSE:Tools"
	EXTRA_ECLASS="obs-download"
fi

inherit eutils ${EXTRA_ECLASS}
unset EXTRA_ECLASS

DESCRIPTION="Script to build SUSE Linux RPMs"
HOMEPAGE="https://build.opensuse.org/package/show?package=build&project=openSUSE%3ATools"

[[ "${PV}" == "9999" ]] || SRC_URI="${OBS_URI}/${PN/suse/obs}-${PV//.}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE="symlink"
[[ "${PV}" == "9999" ]] || \
KEYWORDS="amd64 x86"

RDEPEND="
	virtual/perl-Digest-MD5
	virtual/perl-Getopt-Long
	dev-perl/XML-Parser
	dev-perl/TimeDate
	app-shells/bash
	app-arch/cpio
	app-arch/rpm
"

S="${WORKDIR}/${PN/suse/obs}-${PV//.}"

src_compile() { :; }

src_install() {
	emake DESTDIR="${ED}" pkglibdir=/usr/libexec/suse-build install
	cd "${ED}"/usr
	find bin -type l | while read i; do
		mv "${i}" "${i/bin\//bin/suse-}"
		use !symlink || dosym "${i/bin\//suse-}" "/usr/${i}"
	done
	find share/man/man1 -type f | while read i; do
		mv "${i}" "${i/man1\//man1/suse-}"
		use !symlink || dosym "${i/man1\//suse-}" "/usr/${i}"
	done
	find . -type f -exec sed -i 's|/usr/lib/build|/usr/libexec/suse-build|' {} +

	# create symlink for default build config
	dosym /usr/libexec/suse-build/configs/sl13.1.conf /usr/libexec/suse-build/configs/default.conf
}