dev-python/qscintilla-python/qscintilla-python-2.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/qscintilla-python-2.4.ebuild,v 1.1 2009/06/09 19:03:20 hwoarang Exp $

EAPI="2"

inherit eutils multilib python

MY_P="QScintilla-gpl-${PV/_pre/-snapshot-}"

DESCRIPTION="Python bindings for Qscintilla"
HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
SRC_URI="http://www.riverbankcomputing.co.uk/static/Downloads/QScintilla2/${MY_P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug +qt4"

DEPEND=">=dev-python/sip-4.8
	~x11-libs/qscintilla-${PV}[qt4=]
	qt4? ( >=dev-python/PyQt4-4.5 )
	!qt4? ( >=dev-python/PyQt-3.18 )"
RDEPEND="${DEPEND}"

S="${WORKDIR}"/${MY_P}/Python

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.4-nostrip.patch
}

src_configure() {
	python_version

	local myconf="${python} configure.py
			--destdir=$(python_get_sitedir)/PyQt$(use qt4 && echo 4)
			-n /usr/include
			-o /usr/$(get_libdir)
			-p $(use qt4 && echo 4 || echo 3)
			$(use debug && echo '--debug')"
	echo ${myconf}
	${myconf} || die "configuration failed"
}

src_install() {
	python_need_rebuild
	emake DESTDIR="${D}" install || die "emake install failed"
}