dev-java/xjavadoc/xjavadoc-1.1-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/xjavadoc/xjavadoc-1.1-r2.ebuild,v 1.1 2012/09/27 19:16:46 sera Exp $

EAPI="4"

JAVA_PKG_IUSE="source"
WANT_ANT_TASKS="ant-nodeps"

inherit eutils java-pkg-2 java-ant-2

DESCRIPTION="A standalone implementation of JavaDoc engine suited for XDoclet"
HOMEPAGE="http://xdoclet.sourceforge.net/xjavadoc/"
SRC_URI="mirror://sourceforge/xdoclet/${P}-src.tar.gz
	mirror://gentoo/${P}-supplement.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

COMMON_DEPEND="
	dev-java/commons-collections:0
	dev-java/junit:0"
RDEPEND=">=virtual/jre-1.5
	${COMMON_DEPEND}"
DEPEND=">=virtual/jdk-1.5
	dev-java/javacc
	${COMMON_DEPEND}"

java_prepare() {
	# remove the junit tests, would need xdoclet, causing circular dep
	epatch "${FILESDIR}"/${P}-nojunit.patch

	cd "${S}"/lib || die
	rm -v *.jar || die
	java-pkg_jar-from commons-collections,junit
	java-pkg_jar-from --build-only javacc
}

src_install() {
	java-pkg_dojar target/${PN}.jar
	use source && java-pkg_dosrc src/*
}