1 files changed, 83 insertions, 0 deletions
diff --git a/sys-power/upower/upower-0.9.20.ebuild b/sys-power/upower/upower-0.9.20.ebuild
new file mode 100644
index 000000000000..c898daefb217
--- /dev/null
+++ b/sys-power/upower/upower-0.9.20.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-power/upower/upower-0.9.20.ebuild,v 1.1 2013/03/19 08:34:05 ssuominen Exp $
+
+EAPI=5
+inherit eutils systemd udev
+
+DESCRIPTION="D-Bus abstraction for enumerating power devices and querying history and statistics"
+HOMEPAGE="http://upower.freedesktop.org/"
+SRC_URI="http://${PN}.freedesktop.org/releases/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="doc +introspection ios kernel_FreeBSD kernel_linux systemd"
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.100
+	>=dev-libs/glib-2.22
+	sys-apps/dbus
+	>=sys-auth/polkit-0.110
+	introspection? ( dev-libs/gobject-introspection )
+	kernel_linux? (
+		virtual/libusb:1
+		>=virtual/udev-197[gudev]
+		ios? (
+			>=app-pda/libimobiledevice-1
+			>=app-pda/libplist-1
+			)
+		systemd? ( sys-apps/systemd )
+		)"
+RDEPEND="${COMMON_DEPEND}
+	kernel_linux? (
+		systemd? ( app-shells/bash )
+		!systemd? ( >=sys-power/pm-utils-1.4.1 )
+		)"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	dev-util/intltool
+	virtual/pkgconfig
+	doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.1.2
+		)"
+
+src_prepare() {
+	sed -i -e '/DISABLE_DEPRECATED/d' configure || die
+}
+
+src_configure() {
+	local backend
+
+	if use kernel_linux; then
+		backend=linux
+	elif use kernel_FreeBSD; then
+		backend=freebsd
+	else
+		backend=dummy
+	fi
+
+	econf \
+		--localstatedir="${EPREFIX}"/var \
+		$(use_enable introspection) \
+		--disable-static \
+		$(use_enable !systemd deprecated) \
+		--enable-man-pages \
+		$(use_enable doc gtk-doc) \
+		$(use_enable systemd) \
+		--disable-tests \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		--with-backend=${backend} \
+		$(use_with ios idevice) \
+		"$(systemd_with_utildir)" \
+		"$(systemd_with_unitdir)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" udevrulesdir="$(get_udevdir)"/rules.d install
+
+	dodoc AUTHORS HACKING NEWS README
+	keepdir /var/lib/upower #383091
+	prune_libtool_files
+}