1 files changed, 79 insertions, 0 deletions
diff --git a/net-im/vacuum/vacuum-1.2.2.ebuild b/net-im/vacuum/vacuum-1.2.2.ebuild
new file mode 100644
index 000000000000..0b498a5f6817
--- /dev/null
+++ b/net-im/vacuum/vacuum-1.2.2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/vacuum/vacuum-1.2.2.ebuild,v 1.1 2013/03/10 13:37:10 maksbotan Exp $
+
+EAPI="4"
+LANGS="de pl ru uk"
+
+inherit cmake-utils
+
+DESCRIPTION="Qt4 Crossplatform Jabber client."
+HOMEPAGE="http://code.google.com/p/vacuum-im"
+SRC_URI="http://vacuum-im.googlecode.com/files/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+PLUGINS=" adiummessagestyle annotations autostatus avatars birthdayreminder bitsofbinary bookmarks captchaforms chatstates clientinfo commands compress console dataforms datastreamsmanager emoticons filemessagearchive filestreamsmanager filetransfer gateways inbandstreams iqauth jabbersearch messagearchiver multiuserchat pepmanager privacylists privatestorage registration remotecontrol rosteritemexchange rostersearch servermessagearchive servicediscovery sessionnegotiation shortcutmanager socksstreams urlprocessor vcard xmppuriqueries"
+IUSE="${PLUGINS// / +}"
+for x in ${LANGS}; do
+	IUSE+=" linguas_${x}"
+done
+
+REQUIRED_USE="
+	annotations? ( privatestorage )
+	avatars? ( vcard )
+	birthdayreminder? ( vcard )
+	bookmarks? ( privatestorage )
+	captchaforms? ( dataforms )
+	commands? ( dataforms )
+	datastreamsmanager? ( dataforms )
+	filemessagearchive? ( messagearchiver )
+	filestreamsmanager? ( datastreamsmanager )
+	filetransfer? ( filestreamsmanager datastreamsmanager )
+	pepmanager? ( servicediscovery )
+	registration? ( dataforms )
+	remotecontrol? ( commands dataforms )
+	servermessagearchive? ( messagearchiver )
+	sessionnegotiation? ( dataforms )
+"
+
+RDEPEND="
+	>=dev-qt/qtcore-4.5:4[ssl]
+	>=dev-qt/qtgui-4.5:4
+	>=dev-libs/openssl-0.9.8k
+	adiummessagestyle? ( >=dev-qt/qtwebkit-4.5:4 )
+	net-dns/libidn
+	x11-libs/libXScrnSaver
+	sys-libs/zlib[minizip]
+"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS CHANGELOG README TRANSLATORS"
+
+src_prepare() {
+	# Force usage of system libraries
+	rm -rf src/thirdparty/{idn,minizip,zlib}
+}
+
+src_configure() {
+	# linguas
+	local langs="none;" x
+	for x in ${LANGS}; do
+		use linguas_${x} && langs+="${x};"
+	done
+
+	local mycmakeargs=(
+		-DINSTALL_LIB_DIR="$(get_libdir)"
+		-DINSTALL_SDK=ON
+		-DLANGS="${langs}"
+		-DINSTALL_DOCS=OFF
+		-DFORCE_BUNDLED_MINIZIP=OFF
+	)
+
+	for x in ${PLUGINS}; do
+		mycmakeargs+=( "$(cmake-utils_use ${x} PLUGIN_${x})" )
+	done
+
+	cmake-utils_src_configure
+}