1 files changed, 40 insertions, 0 deletions
diff --git a/media-gfx/pngquant/pngquant-2.3.3.ebuild b/media-gfx/pngquant/pngquant-2.3.3.ebuild
new file mode 100644
index 000000000000..b90e9e7d865c
--- /dev/null
+++ b/media-gfx/pngquant/pngquant-2.3.3.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/pngquant/pngquant-2.3.3.ebuild,v 1.1 2015/02/16 07:49:26 vapier Exp $
+
+EAPI="5"
+
+inherit toolchain-funcs
+
+DESCRIPTION="a command-line utility for converting 24/32-bit PNG images to paletted (8-bit) PNGs"
+HOMEPAGE="http://pngquant.org/"
+SRC_URI="http://pngquant.org/${P}-src.tar.bz2"
+
+LICENSE="HPND rwpng"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug lcms openmp cpu_flags_x86_sse2"
+
+RDEPEND="media-libs/libpng:0=
+	sys-libs/zlib:=
+	lcms? ( media-libs/lcms:2 )"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	tc-export AR CC
+	# Hand rolled configure script, so not all flags are supported.
+	./configure \
+		--prefix="${EPREFIX}/usr" \
+		$(use debug && echo --enable-debug) \
+		$(use_enable cpu_flags_x86_sse2 sse) \
+		$(use openmp && tc-has-openmp && echo --with-openmp) \
+		$(use_with lcms lcms2) \
+		CFLAGS="${CFLAGS} ${CPPFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin ${PN}
+	doman ${PN}.1
+	dodoc CHANGELOG README.md
+}